Error Trying To Remove Shapes

[Ark68]

Is anyone able to shed some light on why I might be getting an "Application-defined or object defined error with the line highlighted in red in the code below?
The odd thing is this had worked flawlessly, but today, it's causing grief. I don't recall changing anything that might have led to this.

Private Sub Workbook_Open()
    'Stop
    ini1
    
    svcCnt = 0
    svcRid = 0
    mbevents = True
    
    'Stop
    With ws_front
        .Activate
        ActiveWindow.ScrollRow = 1
        ActiveWindow.ScrollColumn = 1
        .Unprotect
        With ws_front.Range("J7:BM2206")
            .Clear
            For Each shp In .Parent.Shapes
                If Not Intersect(shp.TopLeftCell, .Cells) Is Nothing Then shp.Delete
            Next shp
        End With
        mbevents = False
        .Range("A1") = "Enter Date"
        .Range("A2") = Format(0, "00000") 'date serial
        .Range("D2") = Format(0, "000") 'record
        .Range("E2:F2").Locked = True
        .Range("E2") = svcRid
        .Range("G2") = svcCnt
        .Range("A3:A5") = ""
        .Range("A19") = "" 'sunset offset
        .Pictures("hidden1").Visible = False
        .Pictures("hidden2").Visible = False
        .Pictures("hidden3").Visible = False
        .Range("P3,R3,Y2,AA2,AG2,AI2,Y3,AA3,Y4,AA4, AG3,AI3") = 0
        ws_staff.Range("D4:R33").Clear
        ws_lists.Range("D2:D101").Clear
        
        mbevents = True
        .Protect
    End With
    
End Sub

When I hover over the line, the error seems to be stemming from "shp.TopLeftCell"
Alias ws_front is recognized as being the proper worksheet.

 

[Ark68]

It turns out that some cells in that range had validations associated with them. I had to delete validations from that range to get it to work again.
Not sure why that would affect the code's ability to identify shapes.

 

[Domenic]

I assume that you're using a List for your data validation, correct? In this case, when .Clear removes the validation within the target range, the drop down object associated with it remains part of the Shapes collection. And so you'll need to account for it.

        With ws_front.Range("J7:BM2206")
            .Clear
            For Each shp In .Parent.Shapes
                If shp.Type = msoFormControl Then
                    shp.Delete
                Else
                    If Not Intersect(shp.TopLeftCell, .Cells) Is Nothing Then shp.Delete
                End If
            Next shp
        End With

However, deleting the form control will delete any and all other data validation of the same type located outside the target range. So, in this case, to avoid deleting them, you could loop through each shape and make sure it's not a msoFormControl before deleting it.

        With ws_front.Range("J7:BM2206")
            .Clear
            For Each shp In .Parent.Shapes
                If shp.Type <> msoFormControl Then
                    If Not Intersect(shp.TopLeftCell, .Cells) Is Nothing Then shp.Delete
                End If
            Next shp
        End With

Hope this helps!