error to show group image to userform

[aap]

i have some issue about how to show group image to userform.
i wrote some code to solve this proble but, error happened. ("error" Set CurrentChart = ThisWorkbook.Sheets("Grafik").Shapes("Group 5").Copy)
please help me to solve my problem, i really appreciate all answer. tks

Sub ChangeChart(ChartName As String)
Dim CurrentChart As Shape
Dim NamaGrafik As String
NamaGrafik = ThisWorkbook.Path & "\temp1.gif"
Set CurrentChart = ThisWorkbook.Sheets("Grafik").Shapes("Group 5").Copy
CurrentChart.Export Filename:=NamaGrafik, Filtername:="GIF"
FGRAFIK.Image1.Picture = LoadPicture(NamaGrafik)
End Sub

 

[KOKOSEK]

Sub SaveShapeAsPicture()
'based on www.thespreadsheetguru.com
Dim cht As ChartObject
Dim ActiveShape As Shape
Dim NamaGrafik As String
NamaGrafik = ThisWorkbook.Path & "\temp1.gif"

Set ActiveShape = ThisWorkbook.Sheets("Grafik").Shapes("Group 5")

'Create a temporary chart object (same size as shape)
  Set cht = ActiveSheet.ChartObjects.Add( _
    Left:=ActiveCell.Left, _
    Width:=ActiveShape.Width, _
    Top:=ActiveCell.Top, _
    Height:=ActiveShape.Height)

'Format temporary chart to have a transparent background
  cht.ShapeRange.Fill.Visible = msoFalse
  cht.ShapeRange.Line.Visible = msoFalse
    
'Copy/Paste Shape inside temporary chart
  ActiveShape.Copy
  cht.Activate
  ActiveChart.Paste
  
'Save chart to User's Desktop as PNG File
  cht.Chart.Export NamaGrafik

'Delete temporary Chart
  cht.Delete

'Re-Select Shape (appears like nothing happened!)
  ActiveShape.Select

End Sub