Error Message: Run Time Error '1004': Unable to set the Hidden property of the Range class

[r0bism123]

First, let me say thanks in advance for looking at this for me. I've been racking my brain trying to figure this out error and I'm stuck.

Below is my code which I am getting the, "Run Time Error '1004': Unable to set the Hidden property of the Range class". What is interesting is that the rows hide/unhide as commanded THEN I get the error message. Annoying. I get the error on line: c.EntireRow.Hidden = True

Thanks again!

Sub Hide_Rows_Containing_Value_All_Sheets()

Dim c As Range
Dim ws As Worksheet

For Each ws In ActiveWorkbook.Worksheets
For Each c In ws.Range("A16:A83").Cells
If c.Value = "" Then
c.EntireRow.Hidden = True
End If
Next c
Next ws

End Sub

Sub Unhide_All_Rows()

For Each ws In ActiveWorkbook.Worksheets
For Each c In ws.Range("A16:A83").Cells
If c.Value = "" Then
c.EntireRow.Hidden = False
End If
Next c
Next ws

End Sub

 

[Fluff]

Are any of your sheets protected?

 

[r0bism123]

Yes, all of my pages are protected and I read something on another site about protected sheets causing issues. So, I tried to unprotecting the workbook and it resulted in Excel crashing. I would get the hour-glass on my cursor and I have to force close it.

 

[Fluff]

Try

Sub Hide_Rows_Containing_Value_All_Sheets()

   Dim c As Range
   Dim ws As Worksheet
   
   For Each ws In ActiveWorkbook.Worksheets
      ws.Unprotect "[COLOR=#ff0000]Pword[/COLOR]"
      For Each c In ws.Range("A16:A83").Cells
         If c.Value = "" Then
         c.EntireRow.Hidden = True
         End If
      Next c
      ws.Protect "[COLOR=#ff0000]Pword[/COLOR]"
   Next ws

End Sub

Change the values in red to match your password.
If Col A has values rather than a formula, this should be quicker

Sub Hide_Rows_Containing_Value_All_Sheets()

   Dim ws As Worksheet
   
   For Each ws In ActiveWorkbook.Worksheets
      ws.Unprotect "Pword"
      ws.Range("A16:A83").SpecialCells(xlBlanks).EntireRow.Hidden = True
      ws.Protect "Pword"
   Next ws

End Sub

 

[r0bism123]

The second one worked perfectly! Thank you so much!

 

[Fluff]

Glad to help & thanks for the feedback