Error Download image by Url Using VBA

[amo]

Hello all

I tried to download the image from the URL and it worked normally.
but if it is run on a 64 bit computer then an error message

I don't know what to do, any ideas?
this is my code

Option Explicit
Private Declare Function URLDownloadToFile Lib "urlmon" _
  Alias "URLDownloadToFileA" (ByVal pCaller As Long, _
  ByVal szURL As String, ByVal szFileName As String, _
  ByVal dwReserved As Long, ByVal lpfnCB As Long) As Long
Dim Ret As Long

Sub Download()
   
    
    Dim strPath As String
    Dim FolderName As String
    Dim x As Integer
    Dim i As Long
    Dim sData As Worksheet: Set sData = Sheets("Sheet17")
    
    Application.DisplayAlerts = False
 
    FolderName = "C:\Try"
 
    With sData
    For i = 1 To 100
        For x = 5 To 12
        Application.Calculation = xlCalculationManual
            If Sheet17.Cells(i, x).Value <> "" Then
                strPath = FolderName & "\" & i  & "-" & x - 4 & ".jpg"
                Ret = URLDownloadToFile(0, Sheet17.Cells(i, x).Value, strPath, 0, 0)
            End If
        Next x
    Next i
    Application.Calculation = xlCalculationAutomatic
    End With

    
Application.DisplayAlerts = True
End Sub

 

[John_w]

Try replacing the URLDownloadToFile declaration with:

#If VBA7 Then
    Private Declare PtrSafe Function URLDownloadToFile Lib "urlmon" _
      Alias "URLDownloadToFileA" (ByVal pCaller As LongPtr, _
      ByVal szURL As String, ByVal szFileName As String, _
      ByVal dwReserved As Long, ByVal lpfnCB As LongPtr) As Long
#Else
    Private Declare Function URLDownloadToFile Lib "urlmon" _
      Alias "URLDownloadToFileA" (ByVal pCaller As Long, _
      ByVal szURL As String, ByVal szFileName As String, _
      ByVal dwReserved As Long, ByVal lpfnCB As Long) As Long
#End If

 

[amo]

Try replacing the URLDownloadToFile declaration with:

#If VBA7 Then
    Private Declare PtrSafe Function URLDownloadToFile Lib "urlmon" _
      Alias "URLDownloadToFileA" (ByVal pCaller As LongPtr, _
      ByVal szURL As String, ByVal szFileName As String, _
      ByVal dwReserved As Long, ByVal lpfnCB As LongPtr) As Long
#Else
    Private Declare Function URLDownloadToFile Lib "urlmon" _
      Alias "URLDownloadToFileA" (ByVal pCaller As Long, _
      ByVal szURL As String, ByVal szFileName As String, _
      ByVal dwReserved As Long, ByVal lpfnCB As Long) As Long
#End If

@John_w Thank you