Error 70 en tiempo de ejecución formularios vba

[Adablablas]

Buenas tardes/dias. estoy haciendo un tipo de base de datos con visual basic. En cierto punto del código me tira el error 70 en tiempo de ejecución "permiso denegado" y no sé bien como solucionarlo. El código
es este

Private Sub TextBox1_Change()
Dim list() As Variant, x As Long, y As Long, coinci As Boolean, k As Integer
coinci = False
y = 0
k = Me.ComboBox1.ListIndex
Select Case k
    Case Is = 0
    
    For x = 2 To Sheets(2).Range("B" & Rows.Count).End(xlUp).Row
        If InStr(1, UCase(Sheets(2).Range("C" & x).Value), UCase(Me.TextBox1.Value)) > 0 Then
            coinci = True
            ReDim Preserve list(15, y)
            list(1, y) = Sheets(2).Range("b" & x).Text
            list(2, y) = Sheets(2).Range("c" & x).Text
            list(3, y) = Sheets(2).Range("d" & x).Text
            list(4, y) = Sheets(2).Range("e" & x).Text
            list(5, y) = Sheets(2).Range("f" & x).Text
            list(6, y) = Sheets(2).Range("g" & x).Text
            list(7, y) = Sheets(2).Range("h" & x).Text
            list(8, y) = Sheets(2).Range("i" & x).Text
            list(9, y) = Sheets(2).Range("j" & x).Text
            list(10, y) = Sheets(2).Range("k" & x).Text
            list(11, y) = Sheets(2).Range("l" & x).Text
            list(12, y) = Sheets(2).Range("m" & x).Text
            list(13, y) = Sheets(2).Range("n" & x).Text
            list(14, y) = Sheets(2).Range("o" & x).Text
            y = y + 1
        End If
    Next
    If coinci = True Then
        Me.ListBox1.list = Application.Transpose(list)
    Else
        Me.ListBox1.RowSource = ""
    End If
End Select

End Sub

Esto es para realizar un filtro en un listbox con un textbox.
Adjunto una foto del formulario ocupado en este

 

[Domenic]

It looks like the error occurs on this line...

Me.ListBox1.list = Application.Transpose(list)

That's probably because the RowSource property of ListBox1 has a value assigned to it. You'll need to make sure that the RowSource property has no value prior assigning list() to Me.ListBox1.list. So, for example...

    If coinci = True Then
        me.ListBox1.RowSource = ""
        Me.ListBox1.list = Application.Transpose(list)
    Else
        Me.ListBox1.RowSource = ""
    End If

Hope this helps!

 

[Adablablas]

It works! thanks u, you saved me

 

[Domenic]

You're very welcome, glad I could help. By the way, unless you have an Option Base 1 statement at the top of your module, this array...

ReDim Preserve list(15, y)

...is being declared as a 0-based array, which means that the indexing starts at 0. It's the same as declaring like this...

ReDim Preserve list(0 to 15, 0 to y)

So you actually have a 16-Row by (y+1)-Column array. If you want to declare a 1-based array so that the indexing starts at 1...

ReDim Preserve list(1 to 15, 1 to y)

Hope this helps!