Error 1004 no data was selected to parse after FileToOpen

[HikingGiraffe]

I have created a macro that asks users to select an excel file to open, and then creates a pivot table with the imported data.

The macro works great if the user selects a file, but if they choose "cancel" I get error code "1004 no data was selected to parse. "
I added a line of code to have a message box pop up telling the user they did not select a file, but after they hit okay the error pops up again which I want to avoid.

Here is what I have so far:

Private Sub Workbook_Open()
Dim FileToOpen As Variant
Dim OpenBook As Workbook
FileToOpen = Application.GetOpenFilename(Title:="Browse for your File & Import Range", FileFilter:="Excel Files (*.xls*),*xls*")
If FileToOpen <> False Then
Set OpenBook = Application.Workbooks.Open(FileToOpen)
OpenBook.Worksheets("Aggregate View").Range("A1:Y300").Copy
ThisWorkbook.Worksheets("AggregateView").Range("A1").PasteSpecial xlPasteValues
OpenBook.Close False
End If
If FileToOpen = False Then MsgBox "Please Select File To Continue"
'The following line will run Macro2
Call NewPivotTableMacro
End Sub

I assume I need to add something after the message box line, but I am not sure what...
Thank you in advance!

 

[Fluff]

How about

Private Sub Workbook_Open()
Dim FileToOpen As Variant
Dim OpenBook As Workbook
FileToOpen = Application.GetOpenFilename(Title:="Browse for your File & Import Range", FileFilter:="Excel Files (*.xls*),*xls*")
If FileToOpen = False Then
    MsgBox "Please Select File To Continue"
    Exit Sub
End If
Set OpenBook = Application.Workbooks.Open(FileToOpen)
OpenBook.Worksheets("Aggregate View").Range("A1:Y300").Copy
ThisWorkbook.Worksheets("AggregateView").Range("A1").PasteSpecial xlPasteValues
OpenBook.Close False

'The following line will run Macro2
Call NewPivotTableMacro
End Sub

 

[HikingGiraffe]

Yes! Exit Sub was the trick. Thank you!

 

[Fluff]

You're welcome & thanks for the feedback.