Easiest way to update formula

[Sufiyan97]

is there any easiest way to update below formula as per expected?

Book3
	A	B
1	Raw	Expected
2	='PL Trend'!C10	=SUM('PL Trend'!C10:D10)
3	='PL Trend'!C11	=SUM('PL Trend'!C11:D11)
4	='PL Trend'!C23	=SUM('PL Trend'!C23:D23)
5	='PL Trend'!C33	=SUM('PL Trend'!C33:D33)
6
7
Sheet1

 

[Joe4]

Here is one way:

Sub MyReplaceFormulaMacro()

    Dim lr As Long
    Dim r As Long
    Dim frm As String
    Dim rw As Long
    Dim frm2 As String

    Application.ScreenUpdating = False

'   Find last row in column A with data
    lr = Cells(Rows.Count, "A").End(xlUp).Row
    
'   Loop through all rows starting with row 2
    For r = 2 To lr
'       Get current formula
        frm = Range("A" & r).Formula
'       Get row from current formula
        rw = Mid(frm, InStr(frm, "!C") + 2)
'       Create new formula
        frm2 = "=SUM(" & Mid(frm, 2) & ":D" & rw & ")"
'       Populate column B with new formula
        Range("B" & r).Formula = frm2
    Next r
    
    Application.ScreenUpdating = True
    
End Sub

 

[Sufiyan97]

Thank you very much Joe,

It works as expected.

 

[Joe4]

You are welcome.