E-mail Macro II

[jade423]

I found the following code on a previous thread. I was wondering how to change it so that it only sends an e-mail of the current worksheet, rather than an e-mail to all worksheets that have an e-mail address. Is there an easier code? Thanks in advance for anyones help.

Sub Outlook_Mail_Every_Worksheet_Body()
' Working in Office 2000-2007
    Dim OutApp As Object
    Dim OutMail As Object
    Dim ws As Worksheet
    With Application
        .EnableEvents = False
        .ScreenUpdating = False
    End With
    Set OutApp = CreateObject("Outlook.Application")
    OutApp.Session.Logon
    For Each ws In ActiveWorkbook.Worksheets
        If ws.Range("P15").Value Like "?*@?*.?*" Then
            Set OutMail = OutApp.CreateItem(0)
            On Error Resume Next
            With OutMail
                .To = ws.Range("P15").Value
                .CC = "noname@asdf1234.biz"
                .BCC = ""
                .Subject = "This is just a test, you may now resume your regular brodcast"
                .HTMLBody = RangetoHTML(ws.UsedRange)
                'You can add a file like this
                '.Attachments.Add ("C:\test.txt")
                .Send    'or use .Display
            End With
            On Error GoTo 0
            Set OutMail = Nothing
        End If
    Next ws
    Set OutApp = Nothing
    With Application
        .EnableEvents = True
        .ScreenUpdating = True
    End With
End Sub
Function RangetoHTML(rng As Range)
' Changed by Ron de Bruin 28-Oct-2006
' Working in Office 2000-2007
    Dim fso As Object
    Dim ts As Object
    Dim TempFile As String
    Dim TempWB As Workbook
 
    TempFile = Environ$("temp") & "/" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"
 
    'Copy the range and create a new workbook to past the data in
    rng.Copy
    Set TempWB = Workbooks.Add(1)
    With TempWB.Sheets(1)
        .Cells(1).PasteSpecial Paste:=8
        .Cells(1).PasteSpecial xlPasteValues, , False, False
        .Cells(1).PasteSpecial xlPasteFormats, , False, False
        .Cells(1).Select
        Application.CutCopyMode = False
        On Error Resume Next
        .DrawingObjects.Visible = True
        .DrawingObjects.Delete
        On Error GoTo 0
    End With
 
    'Publish the sheet to a htm file
    With TempWB.PublishObjects.Add( _
         SourceType:=xlSourceRange, _
         Filename:=TempFile, _
         Sheet:=TempWB.Sheets(1).Name, _
         Source:=TempWB.Sheets(1).UsedRange.Address, _
         HtmlType:=xlHtmlStatic)
        .Publish (True)
    End With
 
    'Read all data from the htm file into RangetoHTML
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
    RangetoHTML = ts.ReadAll
    ts.Close
    RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
                          "align=left x:publishsource=")
 
    'Close TempWB
    TempWB.Close savechanges:=False
 
    'Delete the htm file we used in this function
    Kill TempFile
 
    Set ts = Nothing
    Set fso = Nothing
    Set TempWB = Nothing
End Function

 

[goofy78270]

replace the for each loop for worksheets to ws = activesheet

 

[TheNoocH]

just an FYI...here's a great link for different examples of emailing in Excel

http://www.rondebruin.nl/sendmail.htm

 

[jade423]

replace the for each loop for worksheets to ws = activesheet

Please provide an example. I dont quite understand where to put ws = activesheet. thanks for your help.

 

[goofy78270]

Replace

For Each ws In ActiveWorkbook.Worksheets

with

ws=activesheet

and remove the following

Next ws

This will only run the macro on the currently active sheet. You can also specify what sheet you would like to use by using the following

ws=Sheets("Enter the sheet name here")

 

[jade423]

Thank you, that was my issue, I didnt realize i was replacing that whole part.