Dynamic Sum Vertical and Horizontal By Formula like PivotTable

[LearnMeExcel]

Hi All
i have this Question, i am using dynamic Array Formula to get the Sum of values Vertical and Horizontal and it is working Perfectly, and @Fluff Helped me in Most of them.
But i am trying to add Dynamic Sum Vertical and Horizontal (Subtotals) like PivotTable, and if it is Possible Also Grand.
Can we do that By Dynamic Arrays Formula
this is my data and Formulas

MrExcel Site.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M
1	Invoice Number	Date	Company Name	Amount	Currency	Status			Not Paid	CNY	RUB	USD	HTotal
2	V - 141	15/01/2021	Abc	1153.132	USD	Not Paid			Abc	7,230.19	0.00	1,153.13	0.00
3	V - 157	17/01/2021	FHG	4491.818	EUR	Paid			CDE	7,279.05	4,694.21	0.00	0.00
4	V - 158	26/01/2021	ZJC	6076.498	CNY	Paid			EFG	1,015.34	0.00	0.00	0.00
5	V - 167	16/02/2021	FHG	1105.557	JPY	Paid			MFC	3,381.94	17,550.90	15,054.64	0.00
6	V - 173	17/02/2021	XYZ	7338.599	CNY	Paid			VTotal	57,359.40	57,359.40	57,359.40	57,359.40
7	V - 184	21/02/2021	CDE	2176.351	CNY	Paid
8	V - 194	06/03/2021	THC	7663.309	RUB	Paid
9	V - 204	07/03/2021	ZJC	2955.909	JPY	Paid
10	V - 252	23/03/2021	MFC	4456.528	JPY	Paid
11	V - 278	28/03/2021	ABC	3432.406	RUB	Paid
12	V - 306	28/03/2021	MFC	3381.936	CNY	Not Paid
13	V - 325	31/03/2021	JBR	7563.771	USD	Paid
14	V - 326	31/03/2021	FHG	4094.144	CNY	Paid
15	V - 327	19/04/2021	EFG	7828.469	RUB	Paid
16	V - 330	21/04/2021	MFC	6602.376	USD	Not Paid
17	V - 342	23/04/2021	XYZ	2979.044	RUB	Paid
18	V - 374	25/04/2021	FHG	7932.121	USD	Paid
19	V - 387	05/05/2021	FHG	3621.784	CNY	Paid
20	V - 397	06/05/2021	FHG	4714.177	RUB	Paid
21	V - 415	27/05/2021	JBR	4942.058	JPY	Paid
22	V - 433	27/05/2021	CDE	7999.256	CNY	Paid
23	V - 434	31/05/2021	ABC	2743.007	USD	Paid
24	V - 478	31/05/2021	THC	1122.415	JPY	Paid
25	V - 523	02/06/2021	EFG	4673.887	USD	Paid
26	V - 524	16/06/2021	JBR	2126.972	JPY	Paid
27	V - 531	21/06/2021	MFC	8576.646	RUB	Not Paid
28	V - 544	25/06/2021	MFC	8452.265	USD	Not Paid
29	V - 616	27/06/2021	FHG	6481.728	CNY	Paid
30	V - 637	07/07/2021	CDE	4694.205	RUB	Not Paid
31	V - 671	08/07/2021	MFC	3248.498	RUB	Not Paid
32	V - 677	24/07/2021	ZJC	2986.056	EUR	Paid
33	V - 703	07/08/2021	THC	1342.146	RUB	Paid
34	V - 759	11/09/2021	JBR	4226.128	CNY	Paid
35	V - 770	12/09/2021	ZJC	1949.528	EUR	Paid
36	V - 815	14/09/2021	MFC	5725.759	RUB	Not Paid
37	V - 846	28/09/2021	FHG	8204.793	JPY	Paid
38	V - 861	29/09/2021	MFC	6108.563	USD	Paid
39	V - 887	01/10/2021	FHG	2274.161	EUR	Paid
40	V - 903	10/10/2021	ZJC	5287.774	EUR	Paid
41	V - 910	12/10/2021	Abc	7230.193	CNY	Not Paid
42	V - 913	12/10/2021	ABC	1109.748	RUB	Paid
43	V - 926	29/10/2021	CDE	2849.42	JPY	Paid
44	V - 929	01/11/2021	FHG	4117.116	USD	Paid
45	V - 934	04/11/2021	MFC	4752.744	EUR	Paid
46	V - 937	07/11/2021	XYZ	4851.978	CNY	Paid
47	V - 938	14/11/2021	CDE	7279.049	CNY	Not Paid
48	V - 965	27/11/2021	XYZ	2766.666	JPY	Paid
49	V - 966	28/11/2021	JBR	4601.909	USD	Paid
50	V - 985	06/12/2021	CDE	1092.158	JPY	Paid
51	V - 986	15/12/2021	EFG	1015.34	CNY	Not Paid
iDB-VH

Cell Formulas
Range	Formula
J1:M1	J1	=LET(v,TRANSPOSE(SORT(UNIQUE(FILTER(INDEX(invoice_data,,5),INDEX(invoice_data,,6)="Not Paid")))),IFERROR(INDEX(v,SEQUENCE(,COLUMNS(v)+1)),"HTotal"))
I2:I6	I2	=LET(s,SORT(UNIQUE(FILTER(INDEX(invoice_data,,3),INDEX(invoice_data,,6)="Not Paid"))),IFERROR(INDEX(s,SEQUENCE(ROWS(s)+1)),"VTotal"))
J2:M6	J2	=LET(s,SUMIFS(INDEX(invoice_data,0,4),INDEX(invoice_data,0,3),I2#,INDEX(invoice_data,0,6),"Not Paid",INDEX(invoice_data,0,5),J1#),V,SUMIFS(INDEX(invoice_data,0,4),INDEX(invoice_data,0,3),I2#,INDEX(invoice_data,0,6),"Not Paid"),H,SUMIFS(INDEX(invoice_data,0,4),INDEX(invoice_data,0,6),"Not Paid",INDEX(invoice_data,0,5),J1#),IF(I2#="VTotal",SUM(V),s))
Dynamic array formulas.

Named Ranges
Name	Refers To	Cells
'iDB-VH'!_FilterDatabase	='iDB-VH'!$A$1:$F$51	J1:J2, I2
invoice_data	=OFFSET('iDB-VH'!$A$1,1,0,COUNTA('iDB-VH'!$A:$A)-1,6)	J1:J2, I2

 

[Fluff]

How about like

=LET(s,SUMIFS(INDEX(invoice_data,0,4),INDEX(invoice_data,0,3),I2#,INDEX(invoice_data,0,6),"Not Paid",INDEX(invoice_data,0,5),J1#),V,SUMIFS(INDEX(invoice_data,0,4),INDEX(invoice_data,0,3),I2#,INDEX(invoice_data,0,6),"Not Paid"),H,SUMIFS(INDEX(invoice_data,0,4),INDEX(invoice_data,0,6),"Not Paid",INDEX(invoice_data,0,5),J1#),IF(I2#="VTotal",H,IF(J1#="HTotal",V,s)))

 

[Fluff]

And to get the grand total as well

=LET(s,SUMIFS(INDEX(invoice_data,0,4),INDEX(invoice_data,0,3),I2#,INDEX(invoice_data,0,6),"Not Paid",INDEX(invoice_data,0,5),J1#),V,SUMIFS(INDEX(invoice_data,0,4),INDEX(invoice_data,0,3),INDEX(I2#,SEQUENCE(ROWS(I2#)-1)),INDEX(invoice_data,0,6),"Not Paid"),H,SUMIFS(INDEX(invoice_data,0,4),INDEX(invoice_data,0,6),"Not Paid",INDEX(invoice_data,0,5),INDEX(J1#,SEQUENCE(,COLUMNS(J1#)-1))),IFNA(IF(I2#="VTotal",H,IF(J1#="HTotal",V,s)),SUM(V)))

 

[LearnMeExcel]

And to get the grand total as well

=LET(s,SUMIFS(INDEX(invoice_data,0,4),INDEX(invoice_data,0,3),I2#,INDEX(invoice_data,0,6),"Not Paid",INDEX(invoice_data,0,5),J1#),V,SUMIFS(INDEX(invoice_data,0,4),INDEX(invoice_data,0,3),INDEX(I2#,SEQUENCE(ROWS(I2#)-1)),INDEX(invoice_data,0,6),"Not Paid"),H,SUMIFS(INDEX(invoice_data,0,4),INDEX(invoice_data,0,6),"Not Paid",INDEX(invoice_data,0,5),INDEX(J1#,SEQUENCE(,COLUMNS(J1#)-1))),IFNA(IF(I2#="VTotal",H,IF(J1#="HTotal",V,s)),SUM(V)))

is it Excel or Magic
Really you are amazing @Fluff

A million of Thanks for you

 

[Fluff]

My pleasure.