Dynamic depreciation formula

[David W 123]

Hi everyone.

I have a list of assets (many thousand) with different purchase dates. I would like the cost to be depreciated over 4 months in line with the lower table (% varies by month) and I already have a formula which works well for assets 1 and 2 in the table. However is there a formula which adjusts for number of days, so that for asset 3 (purchased 8 March) : March would be ~23 days of the 40% cost, and April would be ~8 days of the 40% cost and ~23 days of the 30% cost?

Book1
	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q
3	Asset	Cost	Purchase date		Jan-21	Feb-21	Mar-21	Apr-21	May-21	Jun-21	Jul-21	Aug-21	Sep-21	Oct-21	Nov-21	Dec-21
4	1	500,000	01-Feb-21		0	200,000	150,000	100,000	50,000	0	0	0	0	0	0	0
5	2	600,000	01-Mar-21		0	0	240,000	180,000	120,000	60,000	0	0	0	0	0	0
6	3	800,000	08-Mar-21		0	0	0	320,000	240,000	160,000	80,000	0	0	0	0	0
7
8					Cost allocation phasing
9					Month 1	Month 2	Month 3	Month 4
10					40%	30%	20%	10%
Sheet1

Cell Formulas
Range	Formula
F4:Q6	F4	=$C4*IFERROR(INDEX($F$10:$I$10,DATEDIF($D4,F$3,"m")+1),0)

Many thanks for your time and help!
David

 

[Peter_SSs]

See if this does what you want.

21 02 11.xlsm
	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q
3	Asset	Cost	Purchase date		Jan-21	Feb-21	Mar-21	Apr-21	May-21	Jun-21	Jul-21	Aug-21	Sep-21	Oct-21	Nov-21	Dec-21
4	1	500,000	01-Feb-21		0	200,000	150,000	100,000	50,000	0	0	0	0	0	0	0
5	2	600,000	01-Mar-21		0	0	240,000	180,000	120,000	60,000	0	0	0	0	0	0
6	3	800,000	08-Mar-21		0	0	247,742	240,000	160,000	80,000	72,258	0	0	0	0	0
Depreciation

Cell Formulas
Range	Formula
F4:Q6	F4	=IF(COUNTIF($E4:E4,">0")=4,$C4-SUM($E4:E4),$C4*IFERROR(INDEX($F$10:$I$10,DATEDIF($D4-DAY($D4)+1,F$3,"m")+1),0)*IF(EOMONTH($D4,0)=EOMONTH(F$3,0),(DAY(EOMONTH($D4,0))-DAY($D4)+1)/DAY(EOMONTH($D4,0)),1))

 

[David W 123]

Many thanks for your time Peter - much appreciated!

This doesn't quite work. If an asset is purchased 8th March, I would want March to be 23 days of the 40%, and April to be the remainder 8 days of the 40% and 23 days of the 30%, with May being 8 days of the 30% and 23 days of the 20% and so on. Where as your solution results in the correct position for March, but the corrections don't arise until the final month.

Difficult to succinctly explain and conscious of your time. I think I've established a more manual calculation method, so happy for this to be left unless you can think of a swift fix.

Thanks again - David

 

[Peter_SSs]

This doesn't quite work.

Yes, I should have realised that.

See if this monster is better. Note the change to the lookup table in rows 9:10

21 02 11.xlsm
	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q
3	Asset	Cost	Purchase date		Jan-21	Feb-21	Mar-21	Apr-21	May-21	Jun-21	Jul-21	Aug-21	Sep-21	Oct-21	Nov-21	Dec-21
4	1	500,000	01-Feb-21		0	200,000	150,000	100,000	50,000	0	0	0	0	0	0	0
5	2	600,000	01-Mar-21		0	0	240,000	180,000	120,000	60,000	0	0	0	0	0	0
6	3	800,000	08-Mar-21		0	0	245,333	260,473	176,860	99,269	18,065	0	0	0	0	0
7
8
9					Month 0	Month 1	Month 2	Month 3	Month 4	Month 5
10					0%	40%	30%	20%	10%	0%
Depreciation

Cell Formulas
Range	Formula
F4:Q6	F4	=IF(F$3-DAY(F$3)<$D4-DAY($D4),0,MIN($C4*INDEX($F$10:$K$10,MIN(COUNTIF($E4:E4,">0")+2,6))*(DAY(EOMONTH(G$3,0))-DAY($D4)+1)/DAY(EOMONTH(G$3,0))+$C4*INDEX($F$10:$K$10,COUNTIF($E4:E4,">0")+1)*(DAY($D4)-1)/DAY(EOMONTH(F$3,0)),$C4-SUM($E4:E4)))