Dynamic Array referencing previous row

[dreid1011]

Is it possible to reference the previous row in a dynamic array formula? Such as below, in column C, I can add this portion: "-MAX(0,C1)" in C2 to effectively reference the previous value in the next row's calculation.

Book1
	A	B	C	D	E
1
2		10000	-40000		-40000
3		11000	-29000		-29000
4		26000	-3000		-3000
5		7000	4000		4000
6		29000	29000		33000
7
8		50000
Sheet2

Cell Formulas
Range	Formula
E2:E6	E2	=BYROW(SCAN(0,B2:B6,LAMBDA(a,b,b+a)),LAMBDA(r,r-$B$8))
C2:C6	C2	=SUM($B$2:B2)-$B$8-MAX(0,C1)
Dynamic array formulas.

 

[Fluff]

How about

=-SCAN(B8,B2:B6,LAMBDA(a,b,a-b-MIN(0,a)))

 

[dreid1011]

How about

=-SCAN(B8,B2:B6,LAMBDA(a,b,a-b-MIN(0,a)))

Perfect, thank you!

 

[Fluff]

You're welcome & thanks for the feedback.

 

[dreid1011]

Okay, I am sorry, I thought I could figure this part out so I didn't mention it. But how about only showing 0 for the negative amounts? I have tried different combinations of MAX and MIN since you have the "-" preceding SCAN, but it's just skewing the LAMBDA results.

Book1
	F	G
1		Desired
2	-40000	0
3	-29000	0
4	-3000	0
5	4000	4000
6	29000	29000
Sheet2

Cell Formulas
Range	Formula
F2:F6	F2	=-SCAN(B8,B2:B6,LAMBDA(a,b,a-b-MIN(0,a)))
Dynamic array formulas.

 

[Fluff]

How about

=MAP(-SCAN(B8,B2:B6,LAMBDA(a,b,a-b-MIN(0,a))),LAMBDA(m,MAX(0,m)))

 

[dreid1011]

How about

=MAP(-SCAN(B8,B2:B6,LAMBDA(a,b,a-b-MIN(0,a))),LAMBDA(m,MAX(0,m)))

Oy, I was so close. Thank you!

 

[Fluff]

My pleasure.