Duplicate Value with Similar Code

[RichTom44]

Hello, Everyone, how can I formulate the second column to generate a code with the same value or duplicate in the first column?

Value	Code
123	1
123	1
123	1
456	2
456	2
123	1
678	3
678	3
456	2

 

[DanteAmor]

Try

Libro1
	A	B
1	Value	Code
2	123	1
3	123	1
4	123	1
5	456	2
6	456	2
7	123	1
8	678	3
9	678	3
10	456	2
Hoja1

Cell Formulas
Range	Formula
B2:B10	B2	=IF(COUNTIF(A$2:A2,A2)=1,MAX(B$1:B1)+1,VLOOKUP(A2,A$1:B1,2,0))

 

[PeteWright]

Hello @DanteAmor

I had a similar "problem" some time ago and as far as I can remember I used SUMPRODUCT, but I forgot what formula I have used and I cannot find the workbook anymore.

Is it possible to get a result with some combination of SUMPRODUCT?

Thanks in advance

 

[DanteAmor]

how can I formulate the second column to generate a code with the same value or duplicate in the first column?

In 365. It is not necessary to copy the formula down, just put the formula in B2 and it will automatically set all the results.

=XMATCH(A2:A10,UNIQUE(A2:A10),0)

 

[DanteAmor]

In 365. It is not necessary to copy the formula down, just put the formula in B2 and it will automatically set all the results:

=LET(a,A2:A10,XMATCH(a,UNIQUE(a),0))

 

[DanteAmor]

Is it possible to get a result with some combination of SUMPRODUCT?

I can only think of the same formula, but instead of count, use sumproduct, but it is better to use countif

=IF(SUMPRODUCT((A$2:A10=A10)+0)=1,MAX(B$1:B9)+1,VLOOKUP(A10,A$1:B9,2,0))

 

[RichTom44]

Hi Dante, thanks, and I appreciate your help.