Dropping a shape onto a sheet

[BallGazer]

Hi Guys

I'm not that great with VBA but I use the code
<CODE>
Sub circ()
ActiveCell.Offset(0, 0).Select
ActiveSheet.Shapes.AddShape(msoShapeOval, 297#, 390#, 123.75, 104.25). _
Select
Selection.ShapeRange.Fill.Visible = msoFalse
Selection.ShapeRange.Line.Weight = 2#
Selection.ShapeRange.Line.DashStyle = msoLineSolid
Selection.ShapeRange.Line.Style = msoLineSingle
Selection.ShapeRange.Line.Transparency = 0#
Selection.ShapeRange.Line.Visible = msoTrue
Selection.ShapeRange.Line.ForeColor.SchemeColor = 20
Selection.ShapeRange.Line.BackColor.RGB = RGB(255, 255, 255)
End Sub

</CODE>

to draw a no-fill shape on the sheet. I use it to flag areas where I need to come back to check something out. the 297#, 390# in
ActiveSheet.Shapes.AddShape(msoShapeOval, 297#, 390#, 123.75, 104.25).Select

means that the shape appears 297 points from the left etc. I am looking for some code that will drop the shape near to the active cell.

Any ideas greatly appreciated.

BG

 

[VoG]

Try

Sub circ()
ActiveCell.Offset(0, 0).Select
ActiveSheet.Shapes.AddShape(msoShapeOval, 297#, 390#, 123.75, 104.25). _
Select
Selection.ShapeRange.Fill.Visible = msoFalse
Selection.ShapeRange.Line.Weight = 2#
Selection.ShapeRange.Line.DashStyle = msoLineSolid
Selection.ShapeRange.Line.Style = msoLineSingle
Selection.ShapeRange.Line.Transparency = 0#
Selection.ShapeRange.Line.Visible = msoTrue
Selection.ShapeRange.Line.ForeColor.SchemeColor = 20
Selection.ShapeRange.Line.BackColor.RGB = RGB(255, 255, 255)
Selection.Top = ActiveCell.Top
Selection.Left = ActiveCell.Left
End Sub

 

[MickG]

Perhaps:-

ActiveSheet.Shapes.AddShape(msoShapeOval, ActiveCell.Top, ActiveCell.Left, 123.75, 104.25). _
Select

 

[shg]

Sub circ()
    With ActiveCell
        With ActiveSheet.Shapes.AddShape(msoShapeOval, _
                                         .Left, .Top + (.Height - .Width) / 2, _
                                         .Width, .Width)
            .Fill.Visible = msoFalse
            .Line.Weight = 2#
            .Line.DashStyle = msoLineSolid
            .Line.Style = msoLineSingle
            .Line.Transparency = 0#
            .Line.Visible = msoTrue
            .Line.ForeColor.SchemeColor = 20
            .Line.BackColor.RGB = RGB(255, 255, 255)
        End With
    End With
End Sub