Do I use SUM IFS or SUMPRODUCT?

[TxMimi]

column AN is the total$$$ amount
Column S is the complexity - I want to total $$ if complexity is M and S

with the following other conditions
Column G is status - Approved
Column AF - Date Range

This works if I only have one condition
=SUMIFS(RFSLog!$AN$3:$AN$1004, RFSLog!$S$3:$S$1004, "m", RFSLog!$G$3:$G$1004, "Approved", RFSLog!$AF$3:$AF$1004, ">=01/01/2014", RFSLog!$AF$3:$AF$1004, "<=01/31/2014" )

But how do I adjust
RFSLog!$S$3:$S$1004, "m",

if I want a M and S?

Thanks

 

[NeonRedSharpie]

[COLOR=#333333]=SUMIFS(RFSLog!$AN$3:$AN$1004, RFSLog!$S$3:$S$1004, "m", RFSLog!$G$3:$G$1004, "Approved", RFSLog!$AF$3:$AF$1004, ">=01/01/2014", RFSLog!$AF$3:$AF$1004, "<=01/31/2014" ) + [/COLOR][COLOR=#333333]SUMIFS(RFSLog!$AN$3:$AN$1004, RFSLog!$S$3:$S$1004, "s", RFSLog!$G$3:$G$1004, "Approved", RFSLog!$AF$3:$AF$1004, ">=01/01/2014", RFSLog!$AF$3:$AF$1004, "<=01/31/2014" )[/COLOR]

 

[Jonmo1]

Do you man M OR S ?
No single cell can be Both M AND S, it can only be one or the other..

Try

=SUM(SUMIFS(RFSLog!$AN$3:$AN$1004, RFSLog!$S$3:$S$1004, {"m","s"}, RFSLog!$G$3:$G$1004, "Approved", RFSLog!$AF$3:$AF$1004, ">=01/01/2014", RFSLog!$AF$3:$AF$1004, "<=01/31/2014" ))

 

[TxMimi]

@Jonmo1 I should have mentioned that I have a defined list for that column we would either select S,M, or C - technically you are correct I wouldn't be able to choose 2 answers in one cell

BTW, both suggestions yielded the exact same answer. Thank you for your quick responses.

 

[Jonmo1]

I'm not sure what you mean here, can you clarify what your 'defined list' is?

@Jonmo1 I should have mentioned that I have a defined list for that column we would either select S,M, or C

Does this mean it's resolved?

BTW, both suggestions yielded the exact same answer. Thank you for your quick responses.

 

[TxMimi]

@Jonmo1 - yes both example formulas resolved my question.

When I said I had a defined list - I meant that I have a defined name range for a list in data validation

 

[Jonmo1]

Great, glad it worked out.