DMS2DD

[lrobbo314]

DMS2DD converts GPS coordinates from Degrees Minutes Seconds to Decimal Degrees.

=LAMBDA(range,
    MAP(range,
        LAMBDA(x,
            TEXTJOIN(", ",,
                MAP(TEXTSPLIT(x,,", "),
                    LAMBDA(c,
                        LET(
                            a,TEXTSPLIT(CLEANDD(c),," ")+0,
                            deg,INDEX(a,1),
                            min,INDEX(a,2)/60,
                            sec,
                            INDEX(a,3)/3600,ROUND(deg+min+sec,5)
                        )
                    )
                )
            )
        )
    )
)

GPS
	A	B	C
2	Degree Minute Second Input		DMS2DD
3	32° 6' 51.172", -115° 44' 54.78"		32.11421, -114.25145
4	32° 33' 17.431", -113° 27' 4.176"		32.55484, -112.54884
Data

Cell Formulas
Range	Formula
C3:C4	C3	=DMS2DD(A3:A4)
Dynamic array formulas.

Helper function 'CLEANDD'

=LAMBDA(text,
    REDUCE(
        text,
        SEQUENCE(3),
        LAMBDA(
            s,c,
            SUBSTITUTE(s,MID("°'""",c,1),"")
        )
    )
)

 

[lrobbo314]

Noticed an error with this function. This should be correct.

=LAMBDA(range,
    MAP(range,
        LAMBDA(x,
            TEXTJOIN(",",,
                MAP(TEXTSPLIT(x,,","),
                    LAMBDA(c,
                        LET(
                            a,TEXTSPLIT(CLEANDD(c),," ")+0,
                            deg,abs(INDEX(a,1)),
                            min,INDEX(a,2)/60,
                            sec,INDEX(a,3)/3600,
                            if(VALUE(index(a,1))<0,"-","") & ROUND(deg+min+sec,5)
                        )
                    )
                )
            )
        )
    )
)