Displaying years and quarters between 2 dates

[AnotherExcelGuy]

Is there a way to automatically display the following example:

Enter start date - 2020-10-1
Enter end date - 2022-2-3

Display:

2020 - Q4
2021 - Q1
2021- Q2
2021- Q3
2021 - Q4
2022 - Q1

 

[dalvin647]

That was a fun challenge . Try below formula. Thanks!

=UNIQUE(TEXT(B1+SEQUENCE(1+B2-B1,,0),"YYYY")&" - Q"&ROUNDUP(MONTH(B1+SEQUENCE(1+B2-B1,,0))/3,0))

Book2
	A	B
1	Start Date:	2020-10-01
2	End Date:	2022-02-03
3
4	2020 - Q4
5	2021 - Q1
6	2021 - Q2
7	2021 - Q3
8	2021 - Q4
9	2022 - Q1
Sheet1

Cell Formulas
Range	Formula
A4:A9	A4	=UNIQUE(TEXT(B1+SEQUENCE(1+B2-B1,,0),"YYYY")&" - Q"&ROUNDUP(MONTH(B1+SEQUENCE(1+B2-B1,,0))/3,0))
Dynamic array formulas.

 

[lrobbo314]

One way.

AEG
	F	G
5	Start	10/1/2020
6	End	2/3/2022
7
8	2020	Q4
9	2021	Q1
10	2021	Q2
11	2021	Q3
12	2021	Q4
13	2022	Q1
Sheet3

Cell Formulas
Range	Formula
F8:G13	F8	=LET(d,SEQUENCE(G6-G5,,G5),q,"Q"&ROUNDUP(MONTH(d)/3,0),y,YEAR(d),UNIQUE(HSTACK(y,q)))
Dynamic array formulas.