Display TRUE or FALSE if value is the largest that occurred on that day. Bonus: ARRAY FUNCTION!

[btb918]

I have two columns, Column 1 contains dates and Column 2 contains values, like so:

Col1 Col2
1/1/20 5
1/1/20 7
1/2/20 3
1/2/20 9
1/2/20 4
1/3/20 6
1/3/20 6

What formula could I put in Column 3 that would return "TRUE" or "FALSE" if the value in Column 2 is the largest value and not a duplicate value for all the values with the same date? When I mean duplicate value, the first 6 on 1/3/20 would be "TRUE" and the second 6 on 1/3/20 would be "FALSE".

Bonus Points: I'm trying to put this in an array function that I've based on the following website: Extract all rows from a range that meet criteria in one column

So I have the array function making a table out of the rows that have a value equal to or greater than a specified value. It is displaying multiple values that have the same date and I just want the highest value for that day showing.

 

[DanteAmor]

Try this array formula

varios 09jul2020.xlsm
	A	B	C
1	DATE	VALUE	TRUE/FALSE
2	01/01/2020	5	FALSE
3	01/01/2020	7	TRUE
4	02/01/2020	3	FALSE
5	02/01/2020	9	TRUE
6	02/01/2020	4	FALSE
7	03/01/2020	5	FALSE
8	03/01/2020	6	TRUE
9	03/01/2020	5	FALSE
10	03/01/2020	6	FALSE
Hoja6

Cell Formulas
Range	Formula
C2:C10	C2	=AND(B2=MAX(($A$2:$A$12=A2)*($B$2:$B$12)),COUNTIFS($A$2:A2,A2,$B$2:B2,B2)=1)
Press CTRL+SHIFT+ENTER to enter array formulas.

 

[Fluff]

What version of Excel are you using?
Please change your account details to show this, as it affects what functions you have.

If you have Maxifs, another option

+Fluff New.xlsm
	A	B	C
1	DATE	VALUE	TRUE/FALSE
2	01/01/2020	5	FALSE
3	01/01/2020	7	TRUE
4	02/01/2020	3	FALSE
5	02/01/2020	9	TRUE
6	02/01/2020	4	FALSE
7	03/01/2020	5	FALSE
8	03/01/2020	6	TRUE
9	03/01/2020	5	FALSE
10	03/01/2020	6	FALSE
Data

Cell Formulas
Range	Formula
C2:C10	C2	=AND(B2=MAXIFS(B:B,A:A,A2),COUNTIFS(A$2:A2,A2,B$2:B2,B2)=1)

 

[Dave Patton]

For an non-array formula
try
=AGGREGATE(14,6,$B$2:$B$12/($A$2:$A$12=A2),1)=B2