Display the header of the column containing the cell with the lowest value, exclude 0

[ScoobyBear]

Hi,

I'm trying to get a cell do display the header of the column containing the cell with the lowest value but exclude 0-values and negative numbers . I'm struggling with the exclude part. I've come this far:
=INDEX(B1:F1;0,MATCH(MIN(B4:F4),B4:F4,0))
But that include cells with zeros which is useless to me.
So how do I do it!?

 

[PeteWright]

Hi @ScoobyBear I'm not sure what you actually want. Could you give an example please.

 

[PeteWright]

Book1
	B	C	D	E	F
1	H1	H2	H3	H4	H5
2	H3
3
4	7	0	3	-1	5
Sheet1

Cell Formulas
Range	Formula
B2	B2	= INDEX( B1:F1, 0, MATCH( MINIFS(B4:F4, B4:F4, ">0"), B4:F4, 0 ) )

 

[Peter_SSs]

Welcome to the MrExcel board!

If there will only be one column with that low value above zero (or no columns) then you might try the formula in F4:F5 below.
If there could be two or more columns with equal low value >0 then perhaps the formula in F7:F9

23 05 08.xlsm
	A	B	C	D	E	F
1	H1	H2	H3	H4	H5
2
3
4	7	0	3	-1	5	H3
5	-2	-2	-2	-2	-2
6
7	7	0	3	-1	3	H3, H5
8	7	0	3	-1	5	H3
9	-2	-2	-2	-2	-2
Header(s)

Cell Formulas
Range	Formula
F4:F5	F4	=IFNA(INDEX(A$1:E$1,MATCH(MINIFS(A4:E4,A4:E4,">0"),A4:E4,0)),"")
F7:F9	F7	=LET(rw,A7:E7,TEXTJOIN(", ",1,FILTER(A$1:E$1,(rw=MINIFS(rw,rw,">0")),"")))

 

[ScoobyBear]

You guys know your stuff! All three ways worked perfectly!

Thanks!

Btw, thanks for the welcome

 

[Peter_SSs]

All three ways worked perfectly!

Thanks!

You're welcome. Glad we could help. Thanks for the follow-up,