Dictionary Array Issues

[le_vrai_homme]

I'm using a dictionary object with an item that contains an Array. In trying to set the value of array elements, it does not work. It simply stays with an Empty value. Any ideas? I don't seem to have problems setting the value of other non-array items in the dictionary.

Sub test()


Dim a() As Variant
ReDim a(1 To 10)
Set dict = CreateObject("scripting.dictionary")
With dict
    .Item("Array") = a
    .Item("Array")(1) = 0.4
    MsgBox .Item("Array")(1)
End With
Set dict = Nothing


End Sub

 

[sericom]

    .Item("Array" & 1) = 0.4
    MsgBox .Item("Array" & 1)

 

[le_vrai_homme]

That's not an array. That's just a single data point item.

 

[MickG]

Perhaps this:-

Dim a() As Variant, Q
ReDim a(1 To 10)
Dim Dict As Object
Set Dict = CreateObject("scripting.dictionary")
With Dict
    .Item("Array") = a
        Q = .Item("Array")
            Q(1) = 0.4
        .Item("Array") = Q
    MsgBox .Item("Array")(1)
End With
Set Dict = Nothing

 

[le_vrai_homme]

Yes. This works. So it appears that you recall single elements of the array but can't set single elements. To set values, you must set the whole array. This is very helpful. Thank you!