Delete the last character of cells in column "K" if it is equal to "X" or "x"

[harzer]

Hello everyone,
I am asking for support to develop a macro in vba.
I would like to use this Macro to browse all the cells in column "K" and test if the last character is equal to "X" or "x", if this is the case, then we delete this character.
I draw your attention to the fact that the data in my Range is important, hence the need to use tables so that the code can run quickly.
Example :

If Right(arr(i, 11), 1) = "X" Or Right(arr(i, 11), 1) = "x" Then

I remain at your disposal for any further information.
Thank you for your contributions.

Classeur1
	A	B	C	D	E	F	G	H	I	J	K
1	Jeune	Père	Mère	Eleveur	Age	Volière	Cage	Né(e)	Tours	Couleur	Elevage
2	AEM27-002/2024 F	AEM27-010/2021 M	AEM27-017/2023 F	Degallaix Fabrice	0a 5m 18j	5H	12	24-04-2024	4T	Femelle Tt jaune	X
3	AEM27-003/2024 F	AEM27-036/2023 M	HWA96-045/2022 F	Degallaix Fabrice	0a 5m 14j	4B	13	28-04-2024	4T	Femelle Tte jaune	Elevé/AEM27-017/23 Cage 12x
4	AEM27-004/2024 M	AEM27-036/2023 M	HWA96-045/2022 F	Degallaix Fabrice	0a 5m 14j	4B	13	28-04-2024	4T	Mâle Tâche aile droite	Elevé/AEM27-017/23 Cage 12 X
5	AEM27-005/2024 M	AEM27-022/2023 M	AEM27-015/2023 F	Degallaix Fabrice	0a 9m 6j	5H	11	5-01-2024	4T	Mâle Tte jaune	Elevé/AEM27-023/23 Cage 8 X
6	AEM27-006/2024 M	AEM27-022/2023 M	AEM27-015/2023 F	Degallaix Fabrice	0a 9m 6j	5H	11	5-01-2024	4T	Mâle Tâche derrière œil gauche	Elevé/AEM27-023/23 Cage 9
7	AEM27-007/2024 M	AEM27-001/2023 M	AEM27-023/2023 F	Degallaix Fabrice	0a 9m 6j	5H	8	5-01-2024	4T	Mâle Tt jaune	Elevé/AEM27-023/23 Cage 10 x
8	AEM27-008/2024 M	AEM27-033/2022 M	AEM27-009/2023 F	Degallaix Fabrice	0a 9m 6j	5H	4	5-01-2024	4T	Mâle Tâche au dos	Elevé/AEM27-023/23 Cage 11X
9	AEM27-009/2024 M	AEM27-033/2022 M	AEM27-009/2023 F	Degallaix Fabrice	0a 9m 6j	5H	4	5-01-2024	4T	Mâle Tâche au dos	x
Feuil1

 

[Micron]

Not sure what you're asking for because it appears you already have a vba procedure for this (although you only posted one line). Can suggest that all you need is one comparison though, like

If UCase(Right(arr(i, 11), 1)) = "X" Then ...

 

[harzer]

Good evening Micron,
Thank you for your answer.
No I do not have any code implemented, it is a line of code that I found on the internet according to my research according to my request.
Greetings.

 

[jolivanes]

If you use Micron's suggestion in a macro with the use of an array, as indicated in both posts, you might end up with

Sub Maybe()
Dim lr As Long, i As Long
Dim datArr
lr = Cells(Rows.Count, "K").End(xlUp).Row
datArr = Range("K1:K" & lr).Value
    For i = LBound(datArr) To UBound(datArr)
        If UCase(Right(datArr(i, 1), 1)) = "X" Then datArr(i, 1) = Left(datArr(i, 1), Len(datArr(i, 1)) - 1)
    Next i
Range("K1").Resize(UBound(datArr)).Value = datArr
End Sub

 

[Micron]

Maybe this would work for you

Sub removeX()
Dim i As Integer
Dim Lrow As Long
Dim strValue As String

Lrow = Cells(rows.Count, "K").End(xlUp).Row
For i = 1 To Lrow
    strValue = Range("K" & i)
    If UCase(Right(Range("K" & i), 1)) = "X" Then
        strValue = Trim(Left(strValue, Len(strValue) - 1))
        Range("K" & i) = strValue
    End If
Next

End Sub

 

[Fuji]

try

Sub test()
    [k2:k10000] = Evaluate(Replace("if(right(♪)=""X"",left(♪,len(♪)-1),if(♪="""","""",k2:k1000))", "♪", "k2:k10000"))
End Sub

 

[harzer]

Good evening Micron and jolivanes,
Thank you both for your two proposals.
I tested both Macros, they are both functional and give me total satisfaction.
With respect for the work done by each of you, I have a preference for jolivanes' solution for the simple reason that the code is faster, because it uses an array.
My sincere thanks to both of you.

 

[harzer]

Good evening Fuji,
Your solution is just as good and fast.
I also add that it is perfect because it consists of a single line of code that I unfortunately cannot decipher given my level in vba.
I thank you and I am very satisfied and happy with the abundance of good answers.
Greetings.

 

[Fuji]

You are welcome and thanks for the feedback.
I just couldn't edit my code and it should be

Sub test()
    [k2:k10000] = Evaluate(Replace("if(right(♪)=""X"",left(♪,len(♪)-1),if(♪="""","""",♪))", "♪", "k2:k10000"))
End Sub

So that you can replace k2:k1000 to whatever the range you want.