delete rows across multiple tabs

[JamRivera]

Ok so I am still a little new to macros so be gentle and please help it will be greatly appreciated.

I have a macro and I want to delete any row that has the following text in a cell ISN or MTS across 35 tabs. current macro is only deleting ISN and MTS in active sheet.

Sub Delete_Rows_ISN3()
Dim lRow As Long
Dim iCntr As Long
lRow = 390
For iCntr = lRow To 1 Step -1

If Cells(iCntr, 3).Value = "ISN" Then
Rows(iCntr).Delete
End If
Next
End Sub

 

[alansidman]

Are you only concerned with Column C?

 

[alansidman]

Sub Delete_Rows_ISN3()
    Dim ws As Worksheet
    Dim lRow As Long
    Dim iCntr As Long
    lRow = 390
    For Each ws In Worksheets
        For iCntr = lRow To 1 Step -1
            If ws.Cells(iCntr, 3).Value = "ISN" Or ws.Cells(iCntr, 3).Value = "MTS" Then
                Rows(ws.iCntr).Delete
            End If
        Next iCntr
    Next ws
End Sub

 

[JamRivera]

The data is usually listed under column A through C depends on the tab

 

[JamRivera]

I tried your macro but get the following mesg. ​Compile error - method or data not found

 

[alansidman]

ok. When you get the message, click on Debug and tell us which line of code is highlighted. Without this diagnostic, I have no idea what the issue is. This code was untested as you have not provided any data to test on.

 

[JamRivera]

 Sub Delete_Rows_ISN3()
    Dim ws As Worksheet
    Dim lRow As Long
    Dim iCntr As Long
    lRow = 390
    For Each ws In Worksheets
        For iCntr = lRow To 1 Step -1
            If ws.Cells(iCntr, 3).Value = "ISN" Or ws.Cells(iCntr, 3).Value = "MTS" Then
                Rows(ws.iCntr).Delete
            End If
        Next iCntr
    Next ws
End Sub

 

[JamRivera]

Sub Delete_Rows_ISN3() <<<< this line is highlighted
Dim ws As Worksheet
Dim lRow As Long
Dim iCntr As Long
lRow = 390
For Each ws In Worksheets
For iCntr = lRow To 1 Step -1
If ws.Cells(iCntr, 3).Value = "ISN" Or ws.Cells(iCntr, 3).Value = "MTS" Then
Rows(ws.iCntr).Delete <<<< and this part(ws.iCntr). is highlight when I debug
End If
Next iCntr
Next ws
End Sub

 

[MARK858]

Assuming that you have header rows on each sheet...

Sub FilterDel()
    Dim ws As Worksheet
    Application.ScreenUpdating = False
    For Each ws In ActiveWorkbook.Worksheets
        With ws.Range("C1:C" & ws.Range("C" & Rows.Count).End(xlUp).Row)
            .AutoFilter 1, "ISN", xlOr, "MTS"
            On Error Resume Next
            .Offset(1).Resize(.Rows.Count - 1).SpecialCells(12).EntireRow.Delete
            On Error GoTo 0
            .AutoFilter
        End With
    Next
    Application.ScreenUpdating = True
End Sub

As for the code Alan posted the ws is in the wrong place on the line below

Rows([COLOR="#FF0000"]ws.[/COLOR]iCntr).Delete

it should be

[COLOR="#FF0000"]ws.[/COLOR]Rows(iCntr).Delete

 

[JamRivera]

this worked ws.Rows(iCntr).Delete thank you so much appreciate every ones input