Delete row if the cell contains specific data

[HMF009]

Hi every one,

I have workbook have more that 100 sheets, and I need to delete row has specific value in all 100 sheets, note that the specific row is NOT in same range/number

 

[Joe4]

Welcome to the Board!

Can you provide a little more detail?
What do these values we are looking for look like?
Are they found in a specific range (i.e. certain column(s))?
Is an exact match within the cell it is found, or just a partial match (i.e. looking for a word that might be found in a longer sentence)?

 

[HMF009]

Welcome to the Board!

Can you provide a little more detail?
What do these values we are looking for look like?
Are they found in a specific range (i.e. certain column(s))?
Is an exact match within the cell it is found, or just a partial match (i.e. looking for a word that might be found in a longer sentence)?

Hi Joe,

to specify more, in all sheets the column A contains different codes sorted in rows, (e.g. 4092) as a number, but in each sheets this code is not in the same row. I want to make I micro to find it and delete that row from all sheet

 

[Joe4]

Try this code, which will prompt you for the specific value you want to delete:

Sub MyDeleteMacro()

    Dim vl As String
    Dim ws As Worksheet
    Dim rng As Range
    
'   Prompt user for value to look for
    vl = InputBox("Please enter the value you are looking for.")
    
    Application.ScreenUpdating = False
    
'   Loop through all sheets
    For Each ws In Worksheets
        Do
'           Find value
            Set rng = ws.Range("A:A").Find(What:=vl, After:=ws.Range("A1"), LookIn:=xlFormulas, LookAt:= _
                xlWhole, SearchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:=False _
                , SearchFormat:=False)
'           Delete row when found
            If Not rng Is Nothing Then rng.EntireRow.Delete
        Loop Until rng Is Nothing
    Next ws
        
    Application.ScreenUpdating = True
    
    MsgBox "Macro complete!"
        
End Sub

 

[HMF009]

It's Work

Thanks Joe, much appreciated

 

[Joe4]

You are welcome.
Glad I was able to help!