Delete only selected pictures in Excel worksheet

[SerenityNetworks]

I'm using a VBA macro to load 15 pictures in various positions in an Excel worksheet. I'll examine those pictures, delete them, then load some more. The process repeats hundreds of times. This works fine if I want to delete all the pictures that I load. However, I'd like to add some shapes that I don't want deleted. I'd also like to add a 16th picture that I don't want deleted. I'm at a loss as to how to do this (I can manage working with VBA, but I'm not a coder.)

Right now, I'm loading each picture using the following code.

Sub Image15()
    Dim objPicture As Picture
    With Sheet4.Cells(1, 1) ' Picture displays in cell from row, column
        Set objPicture = .Parent.Pictures.Insert(Sheet4.Cells(2, 51).Value) ' Picture path row, column
        objPicture.Top = gvarImage15Top
        objPicture.Left = gvarImage15Left
        objPicture.Width = gvarImage15Width
        objPicture.name = "pic15" ' Trying to see if I can delete by name
    End With
End Sub

As you can see, I've tried naming the picture so I can delete it by name. But if this is the suggested method for deleting specific pictures then please help me with the syntax I need to do it. I've not been able to figure it out.

The following code works fine to delete all pictures, but as I mentioned, my goal is to only delete 15 of the pictures (not the 16th picture or shape I've added to the worksheet.

Sub DeleteImages()
    Dim shape As Excel.shape
    For Each shape In ActiveSheet.Shapes
        shape.Delete
   'Next
End Sub

Any help on this will be appreciated.

Thanks,
Andrew

 

[Domenic]

If you will ever only have pictures and shapes, you could loop through the Pictures collection...

Sub DeleteFirst15Pictures()

    Dim i As Long
    
    On Error Resume Next
    For i = 1 To 15
        ActiveSheet.Pictures(i).Delete
    Next i
    On Error GoTo 0
    
End Sub

Otherwise, try...

Sub DeleteFirst15Pictures()
    Dim shape As shape
    Dim cnt As Long
    cnt = 0
    For Each shape In ActiveSheet.Shapes
        If shape.Type = msoPicture Then
            cnt = cnt + 1
            If cnt <= 15 Then
                shape.Delete
            Else
                Exit For
            End If
        End If
    Next shape
End Sub

Hope this helps!

 

[SerenityNetworks]

Thank you Domenic. Your second option wasn't working. So I tried the following to identify the picture type. I found it was type 11, msoLinkedPicture. I substituted msoPicture with msoLinkedPicture and it worked perfectly.

Thanks again,
Andrew

Sub IdentifyShapes()
    Dim s As shape
    For Each s In ActiveSheet.Shapes
        MsgBox s.Type & vbCrLf & s.name
    Next s
End Sub

 

[Domenic]

That's great. Glad you were able to make it work.

Cheers!