Delete Only Colums containing These words

[berty2000]

Hi guys

Im trying to delete a couple of columns that contain certain words but cant seem to get it to work.
This is what i got so far

Set MR = Range("R10:DA80")    
For Each cell In MR
If cell.Value = "Total Prod Changes" or "All Prod" Then cell.EntireColumn.Delete
Next

 

[mumps]

Try:

Sub deleteCols()
    Application.ScreenUpdating = False
    Dim x As Long, TPC As Range, AP As Range
    For x = 105 To 18 Step -1
        If Not Columns(x).Find("Total Prod Changes") Is Nothing Or Not Columns(x).Find("All Prod") Is Nothing Then
            Columns(x).Delete
        End If
    Next x
    Application.ScreenUpdating = True
End Sub

 

[berty2000]

Perfect thank you buddy

 

[mumps]

You are very welcome.
You replace this line of code:

 Dim x As Long, TPC As Range, AP As Range

with this line:

Dim x As Long

 

[Rick Rothstein]

For those who might find this interesting, the OP's request can be accomplished using a non-looping macro as well...

Sub DeleteCertainColumns()
  With Range("R10:DA80")
    .Replace "All Prod", "#N/A", xlWhole, , False, , False, False
    .Replace "Total Prod Changes", "#N/A", xlWhole, , False, , False, False
    Intersect(.Rows(1), .SpecialCells(xlConstants, xlErrors).EntireColumn).EntireColumn.Delete
  End With
End Sub