Delete everything to the left of text between delimiters

[Innoguide]

I have a text string in excel that is a series of notes delimited by <> following each note

So an example would be:

It is going well - I hope; we'll know more next week<>Project is slipping - more to some<>Project is on track as of 7/7/18<>Well, it's back off track as of 7/15<>

Would very much appreciate any suggestions on how to extract just the last note (rightmost) so the result would be:

Well, it's back off track as of 7/15

 

[Aladin Akyurek]

Something like:

=SUBSTITUTE(REPLACE(A2,1,FIND("#",SUBSTITUTE(A2,"<","#",LEN(A2)-LEN(SUBSTITUTE(A2,"<",""))-1))+1,""),"<>","")

 

[Rick Rothstein]

Assuming none of your entries will be more than 1000 characters long, give this formula a try...

=TRIM(LEFT(RIGHT(SUBSTITUTE(A1,"<>",REPT(" ",1000)),2000),1000))

If you think none of the entries would ever be more than 500 characters in length, this would be more efficient...

=TRIM(LEFT(RIGHT(SUBSTITUTE(A1,"<>",REPT(" ",500)),1000),500))

 

[jtakw]

Hi,

Another way:

Book1
	A	B
1	It is going well - I hope; we'll know more next week<>Project is slipping - more to some<>Project is on track as of 7/7/18<>Well, it's back off track as of 7/15<>	Well, it's back off track as of 7/15
Sheet371

Cell Formulas
Range	Formula
B1	=TRIM(RIGHT(SUBSTITUTE(A1,"<>",REPT(" ",500)),1000))

 

[Innoguide]

Thanks Rick! - Worked perfectly - Is the limit 1000 Characters?

When you say "none of the entries" do you mean the delimited strings or the entire cell?

 

[Innoguide]

Hi jtakw -
Also worked perfectly!

 

[Innoguide]

Hi Aladin -
Formula worked great to find last occurrence of text between delimiters (<>Text string<>)

But I noticed that if there is only one entry (Text string<>) it was returning #value !