Delete entire row if dates are 15 days older than today's

[kelly mort]

Hi, I have been searching the web for some days now and can't figure out the exact code I need.

I want to delete all rows with dates in column B that are older than today's date.

Thank you in advance

 

[dmt32]

Hi

try

Sub DeleteRows()
    Dim c As Range, DeleteRange As Range, DataRange As Range
    Dim LR As Long
    
'change sheet name as required
    With Worksheets("Sheet1")
'find last row in range
        LR = .Cells(.Rows.Count, "B").End(xlUp).Row
'range you are searching
        Set DataRange = .Range("B1:B" & LR)
    End With


    DataRange.EntireRow.Hidden = False


    For Each c In DataRange.Cells
        If IsDate(c.Value) Then
            If Date - DateValue(c.Value) > 15 Then
                If DeleteRange Is Nothing Then
                    Set DeleteRange = c
                Else
                    Set DeleteRange = Union(DeleteRange, c)
                End If
            End If
        End If
    Next c
'delete all matched rows in one go
    If Not DeleteRange Is Nothing Then DeleteRange.EntireRow.Delete
End Sub

Change sheet name shown in RED as required.

Dave

 

[kelly mort]

Okay. Great! !! Working just fine.