Delete entire row based on multiple conditions

[Mange]

Hi all

I want to code the following: the macro has to delete the entire row if the value of the cell in column AR is "ABC", "DEF", "GHI" or "JKL".

My code deletes only the rows containing ABC and GHI..

Could anybody see what's wrong in the code?

Dim i As Range
Dim wsTest As Worksheet
Dim wbDatabase As Workbook
Set wbDatabase = ThisWorkbook
Set wsTest = wbDatabase.Sheets("Overview")

'Delete the information containing ABC, DEF, GHI and JKL.

For Each i In wbDatabase.Sheets("Overview").Range("AR1:AR1000")
If i.Value = "ABC" Or i.Value = "DEF" Or i.Value = "GHI" Or i.Value = "JKL" Then i.EntireRow.Delete

Next i

End Sub

 

[Joe4]

When deleting rows, it is best to work through the range backwards, as deleting rows shifts rows up, as you are moving down the range. So consecutive entries may be missed.
Try this variation:

Sub MyDeleteMacro()
'Delete the information containing ABC, DEF, GHI and JKL.

    Dim LastRow As Long
    Dim myRow As Long
    Dim myValue As String
    Dim wsTest As Worksheet
    Dim wbDatabase As Workbook
    Set wbDatabase = ThisWorkbook
    Set wsTest = wbDatabase.Sheets("Overview")

'   Find last row in column AR
    LastRow = wbDatabase.Sheets("Overview").Cells(Rows.Count, "AR").End(xlUp).Row
    
'   Loop through rows backwards
    For myRow = LastRow To 1 Step -1
        myValue = wbDatabase.Sheets("Overview").Cells(myRow, "AR")
        If myValue = "ABC" Or myValue = "DEF" Or myValue = "GHI" Or myValue = "JKL" Then wbDatabase.Sheets("Overview").Rows(myRow).Delete
    Next myRow

End Sub

 

[Mange]

This works perfectly. Thanks for your help and for explaining the logic!

 

[Joe4]

You are welcome!
Glad I could help!