Delete duplicate rows with VBA

[VbaHell]

Hello all

This line of code removes all my duplicate rows based on the primary key in column "A", at the moment it deletes from the last row upwards but I need it to delete from the first row downwards, reason being is that the newest records are always copied after the last row, is this possible please.

Cells.RemoveDuplicates Columns:=Array(1)

 

[Peter_SSs]

1. Is the data sorted on column A?

2. About how many rows of data do you have?

3. About what proportion of rows will need to be deleted?

4. Just confirming that you want to only keep the last row of each unique value in column A

 

[VbaHell]

Hi Peter

1: At the moment the data is not sorted
2: The rows of data will grow over time, at the moment 300 rows, may well reach about 5,000
3: There always be two duplicates plus some additional new lines - 300 rows means around 130 duplicates with the balance being new lines
4: Yes, the last row for each unique value will always be the latest row that I need to keep

 

[Peter_SSs]

Try this with a copy of your data.

Sub Del_Dupes()
  Dim a As Variant, b As Variant
  Dim d As Object
  Dim nc As Long, i As Long, k As Long
  
  Set d = CreateObject("Scripting.Dictionary")
  d.CompareMode = 1
  nc = Cells.Find(What:="*", After:=Cells(1, 1), LookIn:=xlFormulas, SearchOrder:=xlByColumns, SearchDirection:=xlPrevious).Column + 1
  a = Range("A2", Range("A" & Rows.Count).End(xlUp)).Value
  ReDim b(1 To UBound(a), 1 To 1)
  For i = UBound(a) To 1 Step -1
    If d.exists(a(i, 1)) Then
      b(i, 1) = 1
      k = k + 1
    Else
      d(a(i, 1)) = 1
    End If
  Next i
  If k > 0 Then
    Application.ScreenUpdating = False
    With Range("A2").Resize(UBound(a), nc)
      .Columns(nc).Value = b
      .Sort Key1:=.Columns(nc), Order1:=xlAscending, Header:=xlNo, _
            OrderCustom:=1, MatchCase:=False, Orientation:=xlTopToBottom, DataOption1:=xlSortNormal
      .Resize(k).EntireRow.Delete
    End With
    Application.ScreenUpdating = True
  End If
End Sub