Delete all other columns

[canyon]

I'm trying to write some code that deletes the unspecified columns based on the header and for one reason or another the code does not execute.

wbDest.Activate

lastColumn = Cells(1, Columns.Count).End(xlToLeft).Column

    For i = 1 To lastColumn
        If Cells(1, i).Value <> "Ordered Date:" And Cells(1, i).Value <> "Ship Confirm Date" And Cells(1, i).Value <> "Order Header" And Cells(1, i).Value <> "Customer PO Number (Line)" _
        And Cells(1, i).Value <> "Ordered Item" And Cells(1, i).Value <> "Ordered Item Description" And Cells(1, i).Value <> "Requested Quantity" _
    Then Columns(i).EntireColumn.Delete Shift:=xlToLeft
    
    Next i

 

[Fluff]

What do you mean by "the code does not execute"

 

[canyon]

What do you mean by "the code does not execute"

Sorry - When I run the code the columns don't get deleted.

 

[Joe4]

When deleting rows/columns in a loop, you need to work backwards, otherwise certain columns will get skipped over, i.e.

    For i = lastColumn to 1 Step -1

 

[Fluff]

You can also use select case for that like

wbDest.Activate

lastColumn = Cells(1, Columns.count).End(xlToLeft).Column

    For i = lastColumn To 1 Step -1
      Select Case Cells(1, i).Value
         Case "Ordered Date:", "Ship Confirm Date", "Order Header", "Customer PO Number (Line)", _
               "Ordered Item", "Ordered Item Description", "Requested Quantity"
         Case Else
            Columns(i).EntireColumn.Delete Shift:=xlToLeft
      End Select
    Next i