debug Syntax for dictionaries

[Certified]

Here is a snippet of my code:

Set Results = New Dictionary

For i = 2 To UBound(Mainarray)

TheDate = Mainarray(i, 1)


' If team one is not already in dictionary then add
Results.CompareMode = TextCompare

If Results.Exists(TheDate) Then

'Results(TheDate) = Mainarray(Ecount, 1)
Tran.Update_Amount = Mainarray(i, 8) + Tran.Update_Amount

Else
Tran.Update_Amount = Mainarray(i, 8)
Results.Add Key:=Mainarray(i, 1), Item:=Tran.Update_Amount

End If

Next i

What is the syntax to debug.print this code?

Note: The item is a part of a class.

 

[Norie]

What exactly are you trying to debug/check?

Instead of Debug.Print have you considered using the Local/Watch windows?

 

[Certified]

I am trying to view the items associated to the key. How would I do it with the watch window?

 

[LockeGarmin]

To simply printing the contents of a dictionary to the Immediate window you can use this subroutine:

Sub DebugDictionary(Dictionary As Object)

Dim Key As Variant
  
  For Each Key In Dictionary.keys
    Debug.Print "Key: " & Key & "; Item: " & Dictionary(Key)
  Next Key
  
End Sub

If you want to read the contents form the watch window you would be best served having the following function in your code and putting "WatchDictionary(Results)" in the watch window in the context of your method.

Function WatchDictionary(Dictionary As Object) As Variant

Dim Arr As Variant

Dim Key As Variant
Dim x As Long

  ReDim Arr(0 To Dictionary.Count - 1)
  
  For Each Key In Dictionary.keys
    Arr(x) = "Key: " & Key & "; Item: " & Dictionary(Key)
    x = x + 1
  Next Key
  
  WatchDictionary = Arr
  
End Function