DD2DMS

[lrobbo314]

DD2DMS converts GPS coordinates from Decimal Degrees to Degrees Minutes Seconds

=LAMBDA(range,
    MAP(range,
        LAMBDA(x,
            TEXTJOIN(", ",,
                MAP(TEXTSPLIT(SUBSTITUTE(x," ",""),,","),
                    LAMBDA(c,
                        LET(
                            deg,INT(c),
                            min,INT((c-deg)*60),
                            sec,ROUND((c-deg-min/60)*3600,3),
                            deg&"° "&min&"' "&sec&CHAR(34)
                        )
                    )
                )
            )
        )
    )
)

GPS
	A	B	C
2	Decimal Degree Input		DD2DMS
3	32.1142145,-114.25145		32° 6' 51.172", -115° 44' 54.78"
4	32.554842,-112.54884		32° 33' 17.431", -113° 27' 4.176"
Data

Cell Formulas
Range	Formula
C3:C4	C3	=DD2DMS(A3:A4)
Dynamic array formulas.

 

[lrobbo314]

Noticed an error with this function. This should be correct.

=LAMBDA(range,
    MAP(range,
        LAMBDA(x,
            TEXTJOIN(",",,
                MAP(TEXTSPLIT(SUBSTITUTE(x," ",""),,","),
                    LAMBDA(c,
                        LET(
                            a,abs(c),
                            deg,INT(a),
                            min,INT((a-deg)*60),
                            sec,ROUND((a-deg-min/60)*3600,3),
                            if(value(c)<0,"-","") & deg&"° "&min&"' "&sec&CHAR(34)
                        )
                    )
                )
            )
        )
    )
)