Date Formatter Macro

[myith29]

Hello,

I would like to create a date formatter macro that can be used in multiple worddocuments. I need the macro to do threethings:

• Take a highlighted short date like 6/17/19and convert it to the long date Monday, June 17, 2019;
  
• Have a shortcut key attached (such asCtrl+Shift+D); and
  
• I need the macro to be saved as anindividual program so I can run it with any Word document I open it in and notjust the one I created it in.

Any help on this would be greatly appreciated.
Thank you,

 

[CalcSux78]

Here's a sub that would look at each "word" in a selection, checking for a date value, and convert it to the long date. You could assign the shortcut, then save the document as an add-in.

Sub FixDate()

Dim arr As Variant, i&
arr = Split(Selection.Text, " ")
For i = LBound(arr) To UBound(arr)
    If IsDate(arr(i)) Then arr(i) = Format(arr(i), "DDDD MMMM DD, YYYY")
Next i
Selection.Text = Join(arr, " ")
End Sub

 

[Macropod]

Here's a different approach that won't mess with the formatting of any surrounding text. As coded, it processes every date in the selected range.

Sub LongDates()
Application.ScreenUpdating = False
Dim Rng As Range
With Selection
  Set Rng = .Range
  With .Range
    With .Find
      .ClearFormatting
      .Replacement.ClearFormatting
      .Text = "<[0-9]{1,2}/[0-9]{1,2}/[0-9]{2,4}>"
      .Replacement.Text = ""
      .Forward = True
      .Format = False
      .Wrap = wdFindStop
      .MatchWildcards = True
      .Execute
    End With
    Do While .Find.Found
      If .InRange(Rng) = False Then Exit Do
      If IsDate(.Text) Then .Text = Format(.Text, "DDDD, MMMM D, YYYY")
      .Collapse wdCollapseEnd
      .Find.Execute
    Loop
  End With
End With
Application.ScreenUpdating = True
End Sub

 

[myith29]

Thank you both for your help!