Creating X number of rows on a 2nd tab with populated data

[Xcelling]

How do I take input data from tab A and create X number of rows in tab B to populate the data. X is the value shown as "Count" in column A on the Tab A. Tab B needs to be saved as a csv file to upload to a database. There could be up to 20 rows in input Tab A for a given data set.

MenuSample.xlsx
	A	B	C	D	E	F	G	H
1	Count	Table Letter	Fruit	Meat	Bread
2	2	A	Apple	Steak	Wheat
3	3	B	Orange	Chicken	Sourdough
4	5	C	Pear	Fish	Rye
5	1	D	Plum	Burger	French
6
7
8
9
10
11
12
13
14
Input

MenuSample.xlsx
	A	B	C	D	E	F	G	H	I	J	K
1	Table Letter		Fruit		Meat		Bread
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Ouput

 

[Cubist]

Is this what you mean?

Book2
	A	B	C	D	E	F	G	H	I	J
1	Count	Table Letter	Fruit	Meat	Bread		Table Letter	Fruit	Meat	Bread
2	2	A	Apple	Steak	Wheat		A	Apple	Steak	Wheat
3	3	B	Orange	Chicken	Sourdough		A	Apple	Steak	Wheat
4	5	C	Pear	Fish	Rye		B	Orange	Chicken	Sourdough
5	1	D	Plum	Burger	French		B	Orange	Chicken	Sourdough
6							B	Orange	Chicken	Sourdough
7							C	Pear	Fish	Rye
8							C	Pear	Fish	Rye
9							C	Pear	Fish	Rye
10							C	Pear	Fish	Rye
11							C	Pear	Fish	Rye
12							D	Plum	Burger	French
Sheet1

Cell Formulas
Range	Formula
G2:J12	G2	=TEXTSPLIT(TEXTJOIN(",",,TOCOL(IFS(SEQUENCE(,MAX(A2:A5))<=A2:A5,BYROW(B2:E5,LAMBDA(x,TEXTJOIN("|",,x)))),2)),"|",",")
Dynamic array formulas.

 

[Xcelling]

I need blank spaces between columns G, H, I so I can add data validations (type of apple), (how meat should be cooked), etc

 

[Cubist]

You'd need to adjust the column you want individually like this...

Book2
	A	B	C	D	E	F	G	H	I	J	K	L	M
1	Count	Table Letter	Fruit	Meat	Bread		Table Letter		Fruit		Meat		Bread
2	2	A	Apple	Steak	Wheat		A		Apple		Steak		Wheat
3	3	B	Orange	Chicken	Sourdough		A		Apple		Steak		Wheat
4	5	C	Pear	Fish	Rye		B		Orange		Chicken		Sourdough
5	1	D	Plum	Burger	French		B		Orange		Chicken		Sourdough
6							B		Orange		Chicken		Sourdough
7							C		Pear		Fish		Rye
8							C		Pear		Fish		Rye
9							C		Pear		Fish		Rye
10							C		Pear		Fish		Rye
11							C		Pear		Fish		Rye
12							D		Plum		Burger		French
Sheet1

Cell Formulas
Range	Formula
G2:G12	G2	=TOCOL(IFS(SEQUENCE(,MAX(A2:A5))<=A2:A5,B2:B5),2)
I2:I12	I2	=TOCOL(IFS(SEQUENCE(,MAX(A2:A5))<=A2:A5,C2:C5),2)
K2:K12	K2	=TOCOL(IFS(SEQUENCE(,MAX(A2:A5))<=A2:A5,D2:D5),2)
M2:M12	M2	=TOCOL(IFS(SEQUENCE(,MAX(A2:A5))<=A2:A5,E2:E5),2)
Dynamic array formulas.

 

[Xcelling]

This is a great! Is there a way to add a sequential count for the number of items using a formula J2 =1,J3=2,J4=1,J5=2,J6=3,J7=1, etc

 

[Cubist]

Book2
	G	H	I	J	K	L	M
1	Table Letter		Fruit		Meat		Bread
2	A		Apple	1	Steak		Wheat
3	A		Apple	2	Steak		Wheat
4	B		Orange	1	Chicken		Sourdough
5	B		Orange	2	Chicken		Sourdough
6	B		Orange	3	Chicken		Sourdough
7	C		Pear	1	Fish		Rye
8	C		Pear	2	Fish		Rye
9	C		Pear	3	Fish		Rye
10	C		Pear	4	Fish		Rye
11	C		Pear	5	Fish		Rye
12	D		Plum	1	Burger		French
Sheet1

Cell Formulas
Range	Formula
G2:G12	G2	=TOCOL(IFS(SEQUENCE(,MAX(A2:A5))<=A2:A5,B2:B5),2)
I2:I12	I2	=TOCOL(IFS(SEQUENCE(,MAX(A2:A5))<=A2:A5,C2:C5),2)
J2:J12	J2	=MAP(I2#,LAMBDA(m,COUNTIFS(I2:m,m)))
K2:K12	K2	=TOCOL(IFS(SEQUENCE(,MAX(A2:A5))<=A2:A5,D2:D5),2)
M2:M12	M2	=TOCOL(IFS(SEQUENCE(,MAX(A2:A5))<=A2:A5,E2:E5),2)
Dynamic array formulas.

 

[Xcelling]

Thank you!!!