Creating an array based on number of elements -- MAKEARRAY?

[Scott Huish]

First time trying using MAKEARRAY and I've never used LAMBDA either. Can you please help

If the number was 4

1​	5​
2​	6​
3​	7​
4​	8 ​

If the number was 3, then I was going to use TOROW to get this {1,4,2,5,3,6}

1​	4​
2​	5​
3​	6​

 

[Dave Patton]

I did not use MakeArray but consider the following

Book1
	A	B	C
1
2		1	4
3		2	5
4		3	6
5
6		1	5
7		2	6
8		3	7
9		4	8
10
11
Sheet1

Cell Formulas
Range	Formula
B2:C4	B2	=HSTACK(SEQUENCE(3),SEQUENCE(3,,4))
B6:C9	B6	=HSTACK(SEQUENCE(4),SEQUENCE(4,,5))
Dynamic array formulas.

 

[Eric W]

If you're not just trying to learn how to use MAKEARRAY and LAMBDA, then these versions work too:

Book2
	A	B	C	D	E
1	1	5		1	5
2	2	6		2	6
3	3	7		3	7
4	4	8		4	8
Sheet4

Cell Formulas
Range	Formula
A1:B4	A1	=TRANSPOSE(SEQUENCE(2,4))
D1:E4	D1	=SEQUENCE(4)+{0,4}
Dynamic array formulas.

 

[Sanjeev1976]

Scott, I believe you can use the below :

Book4
	A	B
1	1	5
2	2	6
3	3	7
4	4	8
5
6	1	4
7	2	5
8	3	6
Sheet1

Cell Formulas
Range	Formula
A1:B4	A1	=LET(a,4,MAKEARRAY(a, 2, LAMBDA(row,col, IF(col = 1, row, row + a))))
A6:B8	A6	=LET(a,3,MAKEARRAY(a, 2, LAMBDA(row,col, IF(col = 1, row, row + a))))
Dynamic array formulas.

 

[Scott Huish]

If you're not just trying to learn how to use MAKEARRAY and LAMBDA, then these versions work too:

Book2
	A	B	C	D	E
1	1	5		1	5
2	2	6		2	6
3	3	7		3	7
4	4	8		4	8
Sheet4

Cell Formulas
Range	Formula
A1:B4	A1	=TRANSPOSE(SEQUENCE(2,4))
D1:E4	D1	=SEQUENCE(4)+{0,4}
Dynamic array formulas.

For my ultimate ending need of all this, I used:
=TOROW(TRANSPOSE(SEQUENCE(2,4)))

Book1
	F	G	H	I	J	K	L	M
6	1	5	2	6	3	7	4	8
Sheet1

Cell Formulas
Range	Formula
F6:M6	F6	=TOROW(TRANSPOSE(SEQUENCE(2,4)))
Dynamic array formulas.

Thanks for your help!