Creating a LOG

[AbuFawaz]

I have this code that records the change, its date and the user that did it for all sheets on another sheet, what i need is only the changes in column "N" in a sheet named "Input" to be recorded, below is the code:

Private Sub Workbook_Open()
Sheets("LogDetails").Visible = True
End Sub


Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
If ActiveSheet.Name <> "LogDetails" Then
Application.EnableEvents = False
Sheets("LogDetails").Range("A" & Rows.Count).End(xlUp).Offset(1, 0).Value = ActiveSheet.Name & " - " & Target.Address(0, 0) & " " & Target.Value
Sheets("LogDetails").Range("A" & Rows.Count).End(xlUp).Offset(0, 1).Value = ""
Sheets("LogDetails").Range("A" & Rows.Count).End(xlUp).Offset(0, 2).Value = Environ("username")
Sheets("LogDetails").Range("A" & Rows.Count).End(xlUp).Offset(0, 3).Value = Now
Sheets("LogDetails").Columns("A:D").AutoFit
Application.EnableEvents = True
End If
End Sub



This is my first question on this form I hope I can get some help,

Many thanks in advance.

 

[FormR]

Hi, welcome to the forum!

Try removing the Workbook_SheetChange event code that you have from the "Thisworkbook" code module and instead add the below code to the "Input" sheet code module.

Private Sub Worksheet_Change(ByVal Target As Range)
Dim r As Range, c As Range
Set r = Intersect(Target, Columns("N"))
If Not r Is Nothing Then
    For Each c In r
        With Sheets("LogDetails").Range("A" & Rows.Count).End(xlUp)
            .Offset(1, 0).Value = c.Address & " " & c.Value
            .Offset(1, 1).Value = ""
            .Offset(1, 2).Value = Environ("username")
            .Offset(1, 3).Value = Now
        End With
    Next c
    Sheets("LogDetails").Columns("A:D").AutoFit
End If
End Sub

 

[AbuFawaz]

FormR it is exactly what I needed, many thanks.

 

[FormR]

Great, good to hear