Create SharePoint document folder using VBA in Excel

[willow1985]

I am not familiar with SharePoint but my business has decided to move all records to SharePoint, so I need to be able to modify current Excel Macros to create folders in SharePoint instead of a network drive.
Does anyone know how I can modify the below code to achieve this? My below modifications do not seem to work.

Thank you to anyone who can help.

    sFolder = Worksheets("List").Range("C2").Value & Range("C1").Value
  If Dir(sFolder, vbDirectory) = "" Then
    MkDir sFolder
  End If
  Sheets("Quality Log").Select
  Calculate
  ActiveSheet.Hyperlinks.Add anchor:=Selection, Address:=sFolder

Book1
	B	C
1	Last Quality Record Created:	Q4170
2	Last Quality Record Directory:	https://group.sharepoint.com/sites/StorageTestGroup1/Shared%20Documents/Marcos%20Sheet/Quality%20Records/
3	Directory of All Quality Records:	https://group.sharepoint.com/sites/StorageTestGroup1/Shared%20Documents/Marcos%20Sheet/Quality%20Records/
4
5
6	Directory of OPS Forms	https://group.sharepoint.com/sites/StorageTestGroup1/Shared%20Documents/Marcos%20Sheet/
7		https://group.sharepoint.com/sites/StorageTestGroup1/Shared%20Documents/Marcos%20Sheet/OPS%20097%20Rev%206%20Non%20Conformance%20Report.xlsx
8	Customer Concern OPS Form:	OPS 041 Customer Concerns Rev 7
9	NCR OPS Form:	OPS%20097%20Rev%206%20Non%20Conformance%20Report
10	CAPA OPS Forms	OPS 050 Corrective Action Request Rev 8
List

 

[willow1985]

Found it online, see below. Hopes this helps someone out there:

Sub CreateFolderInSharePointAndUnmount()



    Dim network As Object

    Dim folderPath As String

    Dim folderName As String

    Dim driveLetter As String

    Dim fs As Object

   

    ' Create instance of WScript.Network object

    Set network = CreateObject("WScript.Network")

   

    ' Specify the SharePoint site URL

    Dim sharepointURL As String

    sharepointURL = "https://your_sharepoint_site_url_here/sites/your_site_name_here/library_name"

   

    ' Specify the drive letter to map

    driveLetter = "Z:" ' Change this to your preferred drive letter

   

    ' Map the SharePoint document library to a network drive

    On Error Resume Next

    network.MapNetworkDrive driveLetter, sharepointURL

    If Err.Number <> 0 Then

        MsgBox "Failed to map network drive. Error: " & Err.Description, vbCritical

        GoTo UnmapDrive

    End If

    On Error GoTo 0

   

    ' Specify the folder path within the mapped drive

    folderPath = driveLetter & "\Test"

   

    ' Check if the folder already exists

    If Dir(folderPath, vbDirectory) <> "" Then

        MsgBox "Folder already exists.", vbExclamation

        GoTo UnmapDrive

    End If

   

    ' Create the folder

    Set fs = CreateObject("Scripting.FileSystemObject")

    fs.CreateFolder folderPath

   

    ' Check if folder creation was successful

    If Dir(folderPath, vbDirectory) <> "" Then

        MsgBox "Folder created successfully.", vbInformation

    Else

        MsgBox "Failed to create folder.", vbCritical

        GoTo UnmapDrive

    End If

   

UnmapDrive:

    ' Unmap the network drive

    network.RemoveNetworkDrive driveLetter, True, True

   

    ' Clean up objects

    Set network = Nothing

    Set fs = Nothing

End Sub