Create a formula for countifs that does not count duplicates

[sflem13]

Hello,

I am looking to create a formula that is essentially a countifs with 3 different criteria. Is there something I can add to my formula so that it will not count if "product #" is a duplicate?
The current formula I have in the attached picture returns "4". I am looking for something that will help me eliminate the duplicates from the count and so the returned number in this example would be "2"

 

[ExceLoki]

try this, i've included a solution for 365 and older versions
--------------

Book1
	B	C	D	E	F	G	H	I	J	K	L
1	store type	store number	product #	category	sales qty					365	Older
2	B&M	1	12	tops	5			tops	ECOM	2	2
3	B&M	2	8	tops	6
4	B&M	3	6	pants	0
5	B&M	4	19	pants	4
6	B&M	5	12	tops	9
7	B&M	6	3	pants	3
8	B&M	7	13	dresses	5
9	B&M	8	5	pants	1
10	B&M	9	6	pants	6
11	ECOM	1	8	tops	4
12	ECOM	2	12	tops	7
13	ECOM	3	9	dresses	8
14	ECOM	4	14	dresses	6
15	ECOM	5	2	dresses	0
16	ECOM	6	8	tops	5
17	ECOM	7	16	pants	7
18	ECOM	8	7	pants	6
19	ECOM	9	12	tops	1
Sheet1

Cell Formulas
Range	Formula
K2	K2	=SUM(--(LEN(UNIQUE(FILTER(D:D,(E:E=I2)*(B:B=J2)*(F:F>0),"")))>0))
L2	L2	=SUM(--(FREQUENCY(IF(D1:D19<>"",IF((E1:E19=I2)*(B1:B19=J2)*(F1:F19>0),MATCH(D1:D19,D1:D19,0))),ROW(D1:D19)-ROW(D2)+1)>0))