create a button that do actions

[kerm007]

hello
i create a macro to merge cell , put a border, insert yellow in the cell and type a text
.
how to create a button that i can press when i need to do it for other cell i want to do this action to?
here the code

Sub Tickets_Received()
'
' Tickets_Received Macro
' Merge Cell highlight and Put Text
'
' Keyboard Shortcut: Ctrl+t
'
    ActiveWindow.SmallScroll Down:=72
    Range("I88").Select
    ActiveWindow.SmallScroll Down:=-64
    Range("F28:I28").Select
    With Selection
        .HorizontalAlignment = xlCenter
        .VerticalAlignment = xlBottom
        .WrapText = False
        .Orientation = 0
        .AddIndent = False
        .IndentLevel = 0
        .ShrinkToFit = False
        .ReadingOrder = xlContext
        .MergeCells = False
    End With
    Selection.Merge
    Selection.Borders(xlDiagonalDown).LineStyle = xlNone
    Selection.Borders(xlDiagonalUp).LineStyle = xlNone
    With Selection.Borders(xlEdgeLeft)
        .LineStyle = xlContinuous
        .ColorIndex = 0
        .TintAndShade = 0
        .Weight = xlMedium
    End With
    With Selection.Borders(xlEdgeTop)
        .LineStyle = xlContinuous
        .ColorIndex = 0
        .TintAndShade = 0
        .Weight = xlMedium
    End With
    With Selection.Borders(xlEdgeBottom)
        .LineStyle = xlContinuous
        .ColorIndex = 0
        .TintAndShade = 0
        .Weight = xlMedium
    End With
    With Selection.Borders(xlEdgeRight)
        .LineStyle = xlContinuous
        .ColorIndex = 0
        .TintAndShade = 0
        .Weight = xlMedium
    End With
    Selection.Borders(xlInsideVertical).LineStyle = xlNone
    Selection.Borders(xlInsideHorizontal).LineStyle = xlNone
    With Selection.Interior
        .Pattern = xlSolid
        .PatternColorIndex = xlAutomatic
        .Color = 65535
        .TintAndShade = 0
        .PatternTintAndShade = 0
    End With
    With Selection.Font
        .ColorIndex = xlAutomatic
        .TintAndShade = 0
    End With
    ActiveCell.FormulaR1C1 = "Received"
    Range("F29").Select
End Sub

Thanks

 

[Skyybot]

Run A Macro From A Button

You want an easy way to run a macro. Can you run it from a button on the worksheet?

www.mrexcel.com

 

[kerm007]

hello
is my marco is good and it will do it on any cell i select and apply macro ?

 

[kerm007]

i tries and it does only for a certain cell not the cell i select
i miss something in my code for sure maybe the range ?
Thanks

 

[NoSparks]

Assuming that F28 is the cell that would have been the selected cell for the macro you've posted
change

    ActiveWindow.SmallScroll Down:=72
    Range("I88").Select
    ActiveWindow.SmallScroll Down:=-64
    Range("F28:I28").Select

to

    Selection.Resize(, 4).Select

 

[NoSparks]

I believe the entire code could be reduced to

Sub Tickets_Received()
'
' Tickets_Received Macro
' Merge Cell highlight and Put Text
'
' Keyboard Shortcut: Ctrl+t
'
    Selection.Resize(, 4).Select
    
    With Selection
        .Merge
        .HorizontalAlignment = xlCenter
        .VerticalAlignment = xlBottom
        .BorderAround LineStyle:=xlContinuous, Weight:=xlMedium, ColorIndex:=0
        .Interior.Color = 65535
        .Value = "Recieved"
        .Offset(1).Resize(1, 1).Select
    End With
    
End Sub

 

[kerm007]

ok i will test more cause it remove the conditional formating they way it was supose to do

 

[kerm007]

should replace my code with the last one you gave me ?
Thanks

 

[kerm007]

well its doing it for line 28 but if i selects the line 65 it keep doing it for the line 28 not my sleection
Thanks

 

[NoSparks]

do it for other cell i want to do this action to

You didn't actually explain what that meant
and now you're selecting line 65
so I'm just guessing that you want to be merging the same columns F to I in whatever row you have selected

Sub Tickets_Received()
'
' Tickets_Received Macro
' Merge Cell highlight and Put Text

Dim rowNumber As Long
Dim rng As Range

rowNumber = Selection(1, 1).Row
Set rng = Range("F" & rowNumber).Resize(, 4)

With rng
    .Merge
    .HorizontalAlignment = xlCenter
    .VerticalAlignment = xlBottom
    .BorderAround LineStyle:=xlContinuous, Weight:=xlMedium, ColorIndex:=0
    .Interior.Color = 65535
    .Value = "Recieved"
    .Offset(1).Resize(1, 1).Select
End With
    
End Sub