Counting Even-Odd second digit from the right

[Mike7]

HI,
I have 10 numbers in the range A1:J1
345 687 23 1790 717 546 2581 74 522 841

and formulas that count odd and even numbers in that range

=SUMPRODUCT(--(MOD(A1:J1,2)=1)) with result 6
=SUMPRODUCT(--(MOD(A1:J1,2)<>1)) with result 4

I need a formula which does the same, but only for second digits from the right.
Expected results: 3 odd , 7 even.

Thanks

 

[dreid1011]

Perhaps the formulas in C5:C6 here:

Book1
	A	B	C	D	E	F	G	H	I	J
1	345	687	23	1790	717	546	2581	74	522	841
2
3
4
5	6	Odd	3
6	4	Even	7
Sheet2

Cell Formulas
Range	Formula
A5	A5	=SUMPRODUCT(--(MOD(A1:J1,2)=1))
A6	A6	=SUMPRODUCT(--(MOD(A1:J1,2)<>1))
C5	C5	=SUMPRODUCT(--(MOD(MID(A1:J1,LEN(A1:J1)-1,1),2)=1))
C6	C6	=SUMPRODUCT(--(MOD(MID(A1:J1,LEN(A1:J1)-1,1),2)<>1))

 

[Fluff]

What version of Excel are you using?
I suggest that you update your Account details (or click your user name at the top right of the forum) so helpers always know what Excel version(s) & platform(s) you are using as the best solution often varies by version. (Don’t forget to scroll down & ‘Save’)

 

[Scott Huish]

=SUMPRODUCT(--(MOD(INT(A1:J1/10),2)=1))
=SUMPRODUCT(--(MOD(INT(A1:J1/10),2)=0))

 

[Mike7]

Both work perfect!
Thanks!