Count file and modfication dates

[rawr19911]

i was needing something that would count file's list their names then their path then the modification date- however; the VBA i am looking at does not work it is failing at the first line and saying compile error: user defined type not defined was hoping someone could help or if they have another code that could work

Sub ListFilesinFolder()
Dim FSO As Scripting.FileSystemObject
Dim SourceFolder As Scripting.Folder
Dim FileItem As Scripting.File
SourceFolderName = "C:\Users\Path"
Set FSO = New Scripting.FileSystemObject
Set SourceFolder = FSO.GetFolder(SourceFolderName)
Range("A1:C1") = Array("text file", "path", "Date Last Modified")
i = 2
For Each FileItem In SourceFolder.Files
Cells(i, 1) = FileItem.Name
Cells(i, 2) = FileItem
Cells(i, 3) = FileItem.DateLastModified
i = i + 1
Next FileItem
Set FSO = Nothing
End Sub

 

[rlv01]

saying compile error: user defined type not defined was hoping someone could help or if they have another code that could work

You have to add a reference to the Microsoft Scripting Runtime library to be able to reference the FileSystemObject in that way (early binding).

 

[rawr19911]

You have to add a reference to the Microsoft Scripting Runtime library to be able to reference the FileSystemObject in that way (early binding).

View attachment 97885

perfect thanks!

 

[rlv01]

You can also use late binding, which does not require an explicit library reference (not tested).

Sub ListFilesinFolderLateBinding()
    Dim FSO As Object, SourceFolder As Object, FileItem As Object
    Dim SourceFolderName As String, i As Long 'don't forget to declare all variables
    
    SourceFolderName = "C:\Users\Path"
    
    Set FSO = CreateObject("Scripting.FileSystemObject")
    
    If FSO.FolderExists(SourceFolderName) Then
        Set SourceFolder = FSO.GetFolder(SourceFolderName)
        Range("A1:C1") = Array("text file", "path", "Date Last Modified")
        
        i = 2
        For Each FileItem In SourceFolder.Files
            Cells(i, 1) = FileItem.Name
            Cells(i, 2) = FileItem
            Cells(i, 3) = FileItem.DateLastModified
            i = i + 1
        Next FileItem
    Else
        MsgBox "Folder '" & SourceFolderName & "' not found"
    End If
    Set FSO = Nothing
End Sub

 

[rawr19911]

You can also use late binding, which does not require an explicit library reference (not tested).

Sub ListFilesinFolderLateBinding()
    Dim FSO As Object, SourceFolder As Object, FileItem As Object
    Dim SourceFolderName As String, i As Long 'don't forget to declare all variables
   
    SourceFolderName = "C:\Users\Path"
   
    Set FSO = CreateObject("Scripting.FileSystemObject")
   
    If FSO.FolderExists(SourceFolderName) Then
        Set SourceFolder = FSO.GetFolder(SourceFolderName)
        Range("A1:C1") = Array("text file", "path", "Date Last Modified")
       
        i = 2
        For Each FileItem In SourceFolder.Files
            Cells(i, 1) = FileItem.Name
            Cells(i, 2) = FileItem
            Cells(i, 3) = FileItem.DateLastModified
            i = i + 1
        Next FileItem
    Else
        MsgBox "Folder '" & SourceFolderName & "' not found"
    End If
    Set FSO = Nothing
End Sub

thanks- i have uploaded a new question similar as well- maybe you can help with that one ? you seem to really know your stuff!