Count consecutive runs of numbers in a row.

[Daymo66]

Hi all,
Sorry for such a newb question....
Long time lurker first time poster.

I have a row that contains either C,L,F or a blank cell.
I would like to count the maximum number of letters that appear in a sequence before a blank cell.
e.g.
FCCCFL_FF_LLLCFFFL_ = 8

Appreciate this is very simple, but Id really be most grateful for the help.
KR
D

 

[Fluff]

Hi & welcome to MrExcel.
How about

=LET(data,A2:A100,s,SEQUENCE(ROWS(data)),MAX(FREQUENCY(IF(data<>"",s),IF(data="",s))))

 

[Daymo66]

Thanks for this Fluff.
Ive popped it in and changed A2:A100 to the desired rows (U6:BD6) and its giving me 36, the answer I've counted manually is 7

That's the highest number of of cells in a row containing a C, F or L before there is an empty cell.

What should I adjust.

Really appreciated.
KR
D

 

[Daymo66]

L

L

F

F

C

F

C

C

F

L

L

L

F

L

L

F

C

F

C

F

F

L

F

F

F

 

[Fluff]

Missed it was for a row, so it should be

=LET(data,U6:BD6,s,SEQUENCE(,COLUMNS(data)),MAX(FREQUENCY(IF(data<>"",s),IF(data="",s))))

 

[Daymo66]

Missed it was for a row, so it should be

=LET(data,U6:BD6,s,SEQUENCE(,COLUMNS(data)),MAX(FREQUENCY(IF(data<>"",s),IF(data="",s))))

Excellent, thanks for this. Its still giving me a total of 36, Ive obv missed something, do I need to put C, L, or F in the (data="",s)?
Thanks for your patience.
D

 

[Rick Rothstein]

Here is another formula that will work...

=MAX(LEN(TEXTSPLIT(TRIM(CONCAT(IF(U6:BD6=""," ",U6:BD6)))," ")))

 

[Cubist]

I think this should work as well.

=MAX(SCAN(0,U6:BD6,LAMBDA(a,b,IF(b="",0,a+1))))

 

[Daymo66]

Here is another formula that will work...

=MAX(LEN(TEXTSPLIT(TRIM(CONCAT(IF(U6:BD6=""," ",U6:BD6)))," ")))

That did it!
Great work thanks
D