Copying workbook to new folder

[mrtim2232]

Hi All,

I found this code online and tried to adapt it to suit my needs but i'm not having much luck. I would like to copy my test file to my weekly backup folder and include today's date in the name of the backup file when it has been copied over. Any help would be appreciated, Thanks in advance.

Sub sbCopyingAFile()
Dim FSO
Dim sFile As String
Dim sSFolder As String
Dim sDFolder As String
Dim dFile As String
dFile = sFile & Format(Date, "dd-mm-yyyy")
sFile = "test"
sSFolder = "E:"
sDFolder = "E:\weekly backup"
Set FSO = CreateObject("Scripting.FileSystemObject")
If Not FSO.FileExists(sSFolder & sFile) Then
MsgBox "Specified File Not Found", vbInformation, "Not Found"
ElseIf Not FSO.FileExists(sDFolder & sFile) Then
FSO.CopyFile (sSFolder & dFile), sDFolder, True
MsgBox "Specified File Copied Successfully", vbInformation, "Done!"
Else
MsgBox "Specified File Already Exists In The Destination Folder", vbExclamation, "File Already Exists"
End If
End Sub

 

[Fluff]

Try

Sub sbCopyingAFile()

    Dim FSO
    Dim sFile As String
    Dim sSFolder As String
    Dim sDFolder As String
    Dim dFile As String
    
    sFile = "test"
    dFile = sFile & Format(Date, "dd-mm-yyyy")
    sSFolder = "E:\"
    sDFolder = "E:\weekly backup\"
    Set FSO = CreateObject("Scripting.FileSystemObject")
    If Not FSO.FileExists(sSFolder & sFile & ".[COLOR=#ff0000]xlsm[/COLOR]") Then
        MsgBox "Specified File Not Found", vbInformation, "Not Found"
    ElseIf Not FSO.FileExists(sDFolder & dFile & ".[COLOR=#ff0000]xlsm[/COLOR]") Then
        FSO.CopyFile (sSFolder & sFile & ".[COLOR=#ff0000]xlsm[/COLOR]"), sDFolder & dFile & ".[COLOR=#ff0000]xlsm[/COLOR]", True
        MsgBox "Specified File Copied Successfully", vbInformation, "Done!"
    Else
        MsgBox "Specified File Already Exists In The Destination Folder", vbExclamation, "File Already Exists"
    End If
End Sub

I'm assuming that the test file is an xlsm file, if not change the extensions in red to suit

 

[mrtim2232]

Thankyou! Works like a charm

 

[Fluff]

Glad to help & thanks for the feedback