Copying cell values into a different worksheet on a loop

[detweiler]

As a follow up to the copy cell value to different worksheet with loop post, thanks to @rainbow7766 for getting the initial ask out there and @jolivanes for providing an efficient working solution, which was:

Sub Maybe_So()
Dim dataArr
Dim lr As Long, lc As Long, i As Long, curSh
Dim shT As Worksheet, shM As Worksheet
Application.ScreenUpdating = False
Set shM = Worksheets("Master")
Set shT = Worksheets("Template")
curSh = ActiveSheet.Name
lr = shM.Cells(Rows.Count, 1).End(xlUp).Row
lc = shM.Cells.Find("*", , , , xlByColumns, xlPrevious).Column
dataArr = shM.Cells(1).Resize(lr, lc).Value
    For i = 1 To lr
        shT.Copy After:=Sheets(Sheets.Count)
            With Sheets(Sheets.Count)
                .Name = "Template " & i
                .Cells(2, 2).Value = dataArr(i, 1)
                .Cells(2, 4).Value = dataArr(i, 2)
            End With
    Next i
Sheets(curSh).Activate
Application.ScreenUpdating = True
End Sub

Again, credit where credit is due, the code was supplied by @jolivanes.

While I did get it to work, I do have two questions.

1. My data has a header row and would like to know how to get the macro to start on the second row to pull the values into the new worksheet?
2. How do I get the macro to recognize there is no next row of data so that it doesn't create an empty worksheet?

 

[jolivanes]

Re: "My data has a header row and would like to know how to get the macro to start on the second row to pull the values into the new worksheet?"
Change this

dataArr = shM.Cells(1).Resize(lr, lc).Value

to this

dataArr = shM.Cells(2, 1).Resize(lr - 1, lc).Value

Re" "How do I get the macro to recognize there is no next row of data so that it doesn't create an empty worksheet?"
lr finds the last used cell in Column A so there should not be any empty cells at the end.
If you have empty cells between the first or second cell and the last used cell in column A, you have to let us know.
Maybe this will take care of it if that is indeed the problem.
Insert this

If not dataArr(i, 1)  = "" Then

after the

For i = 1 To lr

line and insert

End If

after the

End With

line