Copy worksheet to .csv save to folder

[AawwYeahh]

I am attempting to merge 2 macros but seem to be missing something
1 the first macro I have uses cell value to create folder and file (works fine)
2 the second macro copy's a worksheet and saves it to default folder as a .csv (works fine)
I am attempting to merge the 2 codes so that when executed macro will create folder
and copy and save worksheet in created folder as a .csv

Sub tstcsv()
Dim strFilename, strDirname, strPathname, strDefpath As String
On Error Resume Next
Worksheets("Dashboard").Select
strDirname = Range("A4").Value
strFilename = Range("B4").Value
strDefpath = "C:\MidSouth\PENDING\"
If IsEmpty(strDirname) Then Exit Sub
If IsEmpty(strFilename) Then Exit Sub
Worksheets("Google").Copy
If Not Right(Defpath, 1) = "\" Then Defpath = Defpath & "\"
If Not Right(strFilename, 4) = ".csv" Then strFilename = strFilename & ".csv"
 
 Application.DisplayAlerts = False
With ActiveWorkbook
MkDir strDefpath & strDirname
strPathname = strDefpath & strDirname & "\" & strFilename 'create total string
ActiveSheet.ExportAsFixedFormat Type:=xlCSV, filename:= _
            strDefpath & strDirname & "\" & strFilename, Quality:=xlQualityStandard, _
            IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=False
 .Close True
  End With
  
  Application.DisplayAlerts = True
 End Sub

 

[DanteAmor]

ActiveSheet.ExportAsFixedFormat Type:=xlCSV, filename:= _ strDefpath & strDirname & "\" & strFilename, Quality:=xlQualityStandard, _ IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=False

That is to save as "pdf"


Try this:

Sub tstcsv()
  Dim strFilename As String, strDirname As String, strPathname As String, strDefpath As String
  
  strDirname = Sheets("Dashboard").Range("A4").Value
  strFilename = Sheets("Dashboard").Range("B4").Value
  strDefpath = "C:\MidSouth\PENDING\"
   
  If strDirname = "" Then MsgBox "strDirname is blank":     Exit Sub
  If strFilename = "" Then MsgBox "strFilename is blank":   Exit Sub
  If Not Right(strDefpath, 1) = "\" Then strDefpath = strDefpath & "\"
  If Not Right(strFilename, 4) = ".csv" Then strFilename = strFilename & ".csv"
  If Dir(strDefpath & strDirname, vbDirectory) = "" Then MkDir strDefpath & strDirname
  strPathname = strDefpath & strDirname & "\" & strFilename 'create total string
    
  Application.DisplayAlerts = False
  Sheets("Google").Copy
  With ActiveWorkbook
    .SaveAs strPathname, xlCSV
    .Close True
  End With
  Application.DisplayAlerts = True
End Sub

 

[AawwYeahh]

THANK YOU!!!!

 

[DanteAmor]

I'm glad to help you. Thanks for the feedback.