Copy worksheet into newly created worksheets

[mri81]

I'm trying to copy a template (from an existing worksheet "BOE_Template") into newly created worksheets from the code below. Basically i have a table, select my range, run it and new worksheets are created based on what is in each cell in that range. For example my table range might be "1.1, 1.2, 1.3 etc". New worksheets are created and the worksheets are renamed to 1.1, 1.2, 1.3). I'd like my template pasted into each of those newly created tabs before it loops back to make the next new worksheet. Hopefully this makes sense and I'm just learning VBA so any help would be appreciated.

Here is my existing code.

Sub Create_BOE_FROM_LIST()
Dim wks As Worksheet
row_ = Selection.Row
col_ = Selection.Column

For Each cell In Range(Cells(row_, col_), Cells(Selection.End(xlDown).Row, col_))
If cell <> "" Then
Set wks = Sheets.Add(after:=ActiveSheet)
wks.Name = cell.Value
End If

Next
End Sub

 

[kevin9999]

See if the following gives you what you want - try it on a copy of your workbook. I'm assuming you know you can't include any of the following characters within valid sheet names:
/ \ [ ] * ? :

Option Explicit
Sub Copy_Template()
    Dim wsTemp As Worksheet, c As Range
    Set wsTemp = Worksheets("BOE_Template")
    For Each c In Selection
        If c = "" Then
            MsgBox "Selection must contain valid sheet names"
            Exit Sub
        End If
        If Evaluate("ISREF('" & c & "'!A1)") Then
            MsgBox "Sheetname " & c & " already exists"
            Exit Sub
        End If
        wsTemp.Copy after:=ActiveSheet
        ActiveSheet.Name = c
    Next c
End Sub

 

[mri81]

See if the following gives you what you want - try it on a copy of your workbook. I'm assuming you know you can't include any of the following characters within valid sheet names:
/ \ [ ] * ? :

Option Explicit
Sub Copy_Template()
    Dim wsTemp As Worksheet, c As Range
    Set wsTemp = Worksheets("BOE_Template")
    For Each c In Selection
        If c = "" Then
            MsgBox "Selection must contain valid sheet names"
            Exit Sub
        End If
        If Evaluate("ISREF('" & c & "'!A1)") Then
            MsgBox "Sheetname " & c & " already exists"
            Exit Sub
        End If
        wsTemp.Copy after:=ActiveSheet
        ActiveSheet.Name = c
    Next c
End Sub

Thanks. I just got it working with additions to my original code below. I'll try your code too.

Sub Create_BOE_FROM_LIST()
Dim wks As Worksheet
Dim templatewks As Worksheet
row_ = Selection.Row
col_ = Selection.Column

Set templatewks = ThisWorkbook.Sheets("BOE Template")

For Each cell In Range(Cells(row_, col_), Cells(Selection.End(xlDown).Row, col_))
If cell <> "" Then
Set wks = Sheets.Add(After:=ActiveSheet)
wks.Name = cell.Value
templatewks.Cells.Copy Destination:=wks.Range("A1")

End If
Next
End Sub