copy to other workbook

[billandrew]

Could use a little help

attempting again here to copy if two criteria is met to another workbook. Using Code below

Sub copyMC()


Dim lastrow As Long
Dim lastrow2 As Long
Dim i As Long

lastrow = Workbooks("Book10").Sheets("Sheet1").Cells(Rows.Count, 1).End(xlUp).Row
lastrow2 = Workbooks("SalesMaster").Sheets("Sheet1").Cells(Rows.Count, 1).End(xlUp).Row


For i = 2 To lastrow

If Cells(i, "A").Value = Date And Cells(i, "B").Value = "Sales" Then

Rows(i).Copy Destination:=Workbooks("Book10").Sheets("Sheet1").Range("A" & lastrow2 + 1)
lastrow2 = Workbooks("SalesMaster").Sheets("sheet1").Cells(Rows.Count, "A").End(xlUp).Row
'Workbooks("Book10").Sheets("Sheet1").Rows(1).Copy Destination:=workbook(sSheets("Sheet1").Rows(1)

The above is an attempt to copy header row

End If


Next i




End Sub

 

[Fluff]

Assuming that you are trying to copy from "SalesMaster" to "Book10"
Try

Sub copyMC()


    Dim lastrow As Long
    Dim i As Long
    Dim Ws As Worksheet
    
    Set Ws = Workbooks("Book10").Sheets("Sheet1")

  
    With Workbooks("SalesMaster").Sheets("sheet1")
        lastrow = .Cells(Rows.Count, 1).End(xlUp).Row
        .Rows(1).Copy Ws.Range("A1")
    
        For i = 2 To lastrow
            If .Cells(i, "A").Value = Date And .Cells(i, "B").Value = "Sales" Then
                .Rows(i).Copy Destination:=Ws.Range("A" & Rows.Count).End(xlUp).Offset(1)
             End If
        Next i
    End With
End Sub

 

[billandrew]

Actually the other way around. Book10 to Salesmaster

 

[Fluff]

Not a problem, try this

Sub copyMC()


    Dim lastrow As Long
    Dim i As Long
    Dim Ws As Worksheet
    
    Set Ws = Workbooks("SalesMaster").Sheets("Sheet1")

  
    With Workbooks("Book10").Sheets("sheet1")
        lastrow = .Cells(Rows.Count, 1).End(xlUp).Row
        .Rows(1).Copy Ws.Range("A1")
    
        For i = 2 To lastrow
            If .Cells(i, "A").Value = Date And .Cells(i, "B").Value = "Sales" Then
                .Rows(i).Copy Destination:=Ws.Range("A" & Rows.Count).End(xlUp).Offset(1)
             End If
        Next i
    End With
End Sub

 

[billandrew]

changed the sheet names works perfect.

Not accustomed to the with and end with, I'll figure it out.

thank you

 

[Fluff]

It's simply a short cut.
Everywhere you have something starting with a . is part of the with.
so

lastrow = Workbooks("Book10").Sheets("sheet1").Cells(Rows.Count, 1).End(xlUp).Row

is the same as

With Workbooks("Book10").Sheets("sheet1")
        lastrow = .Cells(Rows.Count, 1).End(xlUp).Row

Hope that makes some sense

 

[billandrew]

Yes it does.

Thank You again for the code and the explanation.....

 

[Fluff]

Glad to help & thanks for the feedback