Copy template to a New Sheet then rename and increment

[chesterrae]

I have found similar topic that deal with copying an entire sheet in one workbook and pasting it to a NEW sheet while the value on the specific cell increments and adds to the name of the new sheet created. However, the code provided was incomplete and missed the copying of the entire template sheet to new sheet. It only increments and rename the sheet created.

here's the given code:

Sub AddWs()
Dim i As Long, wsName As String, temp As String
Worksheets.Add after:=Worksheets(Worksheets.Count)
wsName = "App1"
If WorksheetExists(wsName) Then
temp = Left(wsName, 3)
i = 1
wsName = temp & i
Do While WorksheetExists(wsName)
i = i + 1
wsName = temp & i
Loop
End If
ActiveSheet.Name = wsName
ActiveSheet.Range("A1").Value = i
End Sub

Function WorksheetExists(wsName As String) As Boolean
On Error Resume Next
WorksheetExists = Worksheets(wsName).Name = wsName
On Error GoTo 0
End Function
Please help.
Thank you!

 

[AlphaFrog]

Replace this line...

Worksheets.Add after:=Worksheets(Worksheets.Count)

With something like this line. Change the name of your "Template" sheet to suit.

Sheets("Template").Copy After:=Sheets(Sheets.Count)

 

[chesterrae]

Thank you so much!!! works perfectly!!

 

[jo_hivera]

I've been using this code but I need to edit the sheet names before printing for project tracking purposes.
Would it be possible to tweak this code to add other elements to the name?
for example: App1-20_RA
something along the lines of wsName & "-20_RA"?

 

[AlphaFrog]

Sub AddWs()
    Dim i As Long, wsName As String
    Sheets("Template").Copy After:=Sheets(Sheets.Count)
    Do
        i = i + 1
        wsName = "App" & i & "-20_RA"
    Loop While WorksheetExists(wsName)
    ActiveSheet.Name = wsName
    ActiveSheet.Range("A1").Value = i
End Sub

Function WorksheetExists(wsName As String) As Boolean
    On Error Resume Next
    WorksheetExists = Worksheets(wsName).Name = wsName
    On Error GoTo 0
End Function

 

[jo_hivera]

Sub AddWs()
    Dim i As Long, wsName As String
    Sheets("Template").Copy After:=Sheets(Sheets.Count)
    Do
        i = i + 1
        wsName = "App" & i & "-20_RA"
    Loop While WorksheetExists(wsName)
    ActiveSheet.Name = wsName
    ActiveSheet.Range("A1").Value = i
End Sub

Function WorksheetExists(wsName As String) As Boolean
    On Error Resume Next
    WorksheetExists = Worksheets(wsName).Name = wsName
    On Error GoTo 0
End Function

Works wonders and I see what I was doing wrong! Thank you so much!