Copy string to windows clipboard VBA

[Jurg55]

Hi,

I would like to have a code that copies a string to the windows clipboard using VBA. So i can paste the clipboard to other software then excel.

My code is now the following:

    Dim strText As String
    strText = FilePath

    With New DataObject
        .SetText strText
        .PutInClipboard
    End With

If I test the code it works for me, but could you check it and make changes if this code is not how it SHOULD be.

Thank you!

 

[Domenic]

Yes, your code looks fine and works for me too . . .

 

[Artik]

There may have been problems using DataObject for a long time. Here is another way to copy using Microsoft HTML Object Library.

Sub Test()
    Dim var1
    Dim var2

    var1 = "Hello world."
    var2 = 123

    'transfer to clipboard
    Clipboard var1 & vbLf & var2

    'read from clipboard
    MsgBox Clipboard
End Sub


Function Clipboard(Optional s As String) As String
    Dim v

    v = s  'for 64-bit.

    With CreateObject("htmlfile")
        With .parentWindow.clipboardData
            Select Case True
                Case Len(s) > 0: .setData "text", v
                Case Else: Clipboard = .GetData("text")
            End Select
        End With
    End With
End Function

Artik