Copy Selected Data and Paste to the Last Row of Another Sheet

[Saravana]

Have one row in "Copy" sheet and 2 rows in "Master" sheet.
In Master sheet after the last row i mean in 3rd row want the data present from A1 to S column to be pasted from Copy sheet.

 

[Yongle]

Welcome to the forum
Try this VBA solution

Sub CopyRow()
    Sheets("Master").Range("A1:S1").Copy Sheets("Copy").Range("A" & Rows.Count).End(xlUp).Offset(1)
End Sub

For values to be pasted

    Sheets("Master").Range("A1:S1").Copy
    With Sheets("Copy").Range("A" & Rows.Count).End(xlUp).Offset(1)
        .PasteSpecial (xlPasteAll)
        .PasteSpecial (xlPasteValues)
    End With

 

[Yongle]

Oops
I missed your "Selected Data" constraint because it is in the title but not in the detail in post#1

This copies columns A:S for all selected rows to sheet "Copy"
Selecting one cell in any column is sufficient

Sub CopyActiveRow()
    Range("A1:S1").Offset(ActiveCell.Row - 1).Resize(Selection.Rows.Count).Copy
    With Sheets("Copy").Range("A" & Rows.Count).End(xlUp).Offset(1)
        .PasteSpecial (xlPasteAll)
        .PasteSpecial (xlPasteValues)
    End With
End Sub

 

[Saravana]

Master is source sheet which has 2 rows
Copy is the new data which has 1 row (may also have many rows , it should copy till last row and then append to last row to Master sheet) , need to insert this row to Master sheet as a third row. Can you explain as i am new to macro

 

[Saravana]

Master is one sheet and Copy is the another sheet in the same excel

 

[Yongle]

this will copy FROM sheet COPY to sheet Master

Sub CopyActiveRow()
    Range("A1:S1").Offset(ActiveCell.Row - 1).Resize(Selection.Rows.Count).Copy
    With Sheets("Master").Range("A" & Rows.Count).End(xlUp).Offset(1)
        .PasteSpecial (xlPasteAll)
        .PasteSpecial (xlPasteValues)
    End With
End Sub

 

[Saravana]

Can you explain the above code and where you have mentioned the sheet name ("Copy").

 

[Yongle]

where you have mentioned the sheet name ("Copy").

Rows being selected by user are on sheet "copy"
So sheet "Copy" is the active sheet
(Unless qualified with a sheet reference) ranges automatically refer to the active sheet
Range("A1:S1").Offset(ActiveCell.Row - 1).Resize(Selection.Rows.Count).Copy

Sub CopyActiveRow()
'The active cell is the FIRST cell in a selected range
'with range A6:A8 selected, ActiveCell =A6
'ActiveCell.Row is the row number of that cell = 6
'Selection.Rows.Count = the count of rows in the selected range = 3  (rows 6,7,8)
'A1:S1 is offset by 5 rows ( ie ActiveCell.Row 6 MINUS 1 = 5)  = A6:S6
'A6:S6 is then resized to 3 rows = A6:S8
' that range is copied
    Range("A1:S1").Offset(ActiveCell.Row - 1).Resize(Selection.Rows.Count).Copy
'standard technique to find last cell in column A and then offseting by one row
' same as putting cusor in cell A1048576 followed by {END}{UP arrow}{DOWN arrow}
    With Sheets("Master").Range("A" & Rows.Count).End(xlUp).Offset(1)
'paste everything including formula
        .PasteSpecial (xlPasteAll)
'overwrite with values
        .PasteSpecial (xlPasteValues)
    End With
End Sub

 

[Karvzla305]

Rows being selected by user are on sheet "copy"
So sheet "Copy" is the active sheet
(Unless qualified with a sheet reference) ranges automatically refer to the active sheet
Range("A1:S1").Offset(ActiveCell.Row - 1).Resize(Selection.Rows.Count).Copy

Sub CopyActiveRow()
'The active cell is the FIRST cell in a selected range
'with range A6:A8 selected, ActiveCell =A6
'ActiveCell.Row is the row number of that cell = 6
'Selection.Rows.Count = the count of rows in the selected range = 3  (rows 6,7,8)
'A1:S1 is offset by 5 rows ( ie ActiveCell.Row 6 MINUS 1 = 5)  = A6:S6
'A6:S6 is then resized to 3 rows = A6:S8
' that range is copied
    Range("A1:S1").Offset(ActiveCell.Row - 1).Resize(Selection.Rows.Count).Copy
'standard technique to find last cell in column A and then offseting by one row
' same as putting cusor in cell A1048576 followed by {END}{UP arrow}{DOWN arrow}
    With Sheets("Master").Range("A" & Rows.Count).End(xlUp).Offset(1)
'paste everything including formula
        .PasteSpecial (xlPasteAll)
'overwrite with values
        .PasteSpecial (xlPasteValues)
    End With
End Sub

Hi, I am trying to adapt this code to follow the same function. But I need it to actually go into a table and then select each element from the last row and copy each cell into 2 different sheets.

I have not had much luck. I loved the concept of it using the selected one but I cannot seem to be able to adapt it. Is there a way?