Copy rows with "like" values in A column into new sheets

[ExcelNoob11]

I have a workbook with a table that I need to subdivide into individual sheets.

The table has 7 columns. In column A it has the name of a device.

For example:
[TABLE="width: 500"]
<tbody>[TR]
[TD]ColumnA[/TD]
[TD]ColumnB[/TD]
[TD]ColumnC[/TD]
[TD]ColumnD[/TD]
[TD]ColumnE[/TD]
[TD]ColumnF[/TD]
[TD]ColumnG[/TD]
[/TR]
[TR]
[TD]Device1[/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[/TR]
[TR]
[TD]Device1[/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[/TR]
[TR]
[TD]Device1[/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[/TR]
[TR]
[TD]Device2[/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[/TR]
[TR]
[TD]Device2[/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[/TR]
[TR]
[TD]Device3[/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[/TR]
</tbody>[/TABLE]

I'd like to take all the rows with "Device1" and copy them to a new sheet with "Device1" as the name of the sheet. Then proceed to do it for Device2, Device3, and DevinceN.

Can anyone point me in the right direction?

Kind regards,
ExcelNoobie

 

[mumps]

This macro assumes you have headers in row 1 and the sheet with the data is named "Sheet1".

Sub CreateSheet()
    Application.ScreenUpdating = False
    Dim bottomA As Long
    bottomA = Sheets("Sheet1").Range("A" & Rows.Count).End(xlUp).Row
    Dim rName As Range
    Dim ws As Worksheet
    Dim rngUniques As Range
    Sheets("Sheet1").Range("A1:A" & bottomA).AdvancedFilter Action:=xlFilterInPlace, CriteriaRange:=Range _
        ("A1:A" & bottomA), Unique:=True
    Set rngUniques = Sheets("Sheet1").Range("A2:A" & bottomA).SpecialCells(xlCellTypeVisible)
    If Sheets("Sheet1").AutoFilterMode = True Then Sheets("Sheet1").AutoFilterMode = False
    For Each rName In rngUniques
        Set ws = Nothing
        On Error Resume Next
        Set ws = Worksheets(rName.Value)
        On Error GoTo 0
        If ws Is Nothing Then
            Worksheets.Add(After:=Sheets(Sheets.Count)).Name = rName.Value
            Sheets("Sheet1").Rows(1).Copy Cells(1, 1)
        End If
    Next rName
    For Each rName In rngUniques
        Sheets(rName.Value).UsedRange.Offset(1, 0).ClearContents
        Sheets("Sheet1").Range("A1:A" & bottomA).AutoFilter Field:=1, Criteria1:=rName
        Sheets("Sheet1").Range("A2:A" & bottomA).SpecialCells(xlCellTypeVisible).EntireRow.Copy Sheets(rName.Value).Cells(Rows.Count, "A").End(xlUp).Offset(1, 0)
        If Sheets("Sheet1").AutoFilterMode = True Then Sheets("Sheet1").AutoFilterMode = False
    Next rName
    Application.ScreenUpdating = True
 End Sub

 

[ExcelNoob11]

Looks like that worked.. you were much further than I was..

 

[mumps]

Glad it worked for you.

 

[ExcelNoob11]

Was able to follow most of it except here:

[COLOR=#333333]Sheets(rName.Value).UsedRange.Offset(1, 0).ClearContents[/COLOR]

Are you just removing the column headers?

 

[mumps]

That line of code clears everything except the headers. This allows you to change or update the data in Sheet1 and then when you run the macro again, Sheet2 will be populated with all the new data.